从 C++ 访问 OS X 上标准目录的现代、标准、规范方法是什么，例如 ~/Library/Application Support 或 ~/Library/Preferences ？

我看到提到使用 CoreServices ，但它也提到它已被弃用，我很难找到可以让我做更多事情的文档，而不仅仅是将代码粘贴进去。

我找到了使用 Objective C++ 的提及，但是关于该选项的大部分信息都围绕着从 Objective C 调用 C++ 代码，而且 Apple 关于它的文档似乎相当稀疏​​，或者至少我没有成功找到它.

最佳答案

好吧，有一个鲜为人知的 NSSystemDirectories.h(位于 /usr/include/NSSystemDirectories.h) header ，它存在于我检查过的每个 OS X 版本上一直回到 OS X 10.3。它是 libc 的一部分:http://opensource.apple.com//source/Libc/Libc-825.40.1/include/NSSystemDirectories.h

它提供了一个 C API，尽管创建一个 Objective-C++ 包装器并不难:创建一个纯 C++ 接口(interface)并在实现中使用 Objective-C。

文件夹管理器.h:

#include <stdio.h>
namespace fm {
    enum {
        NSApplicationDirectory = 1,
        NSDemoApplicationDirectory,
        NSDeveloperApplicationDirectory,
        NSAdminApplicationDirectory,
        NSLibraryDirectory,
        NSDeveloperDirectory,
        NSUserDirectory,
        NSDocumentationDirectory,
        NSDocumentDirectory,
        NSCoreServiceDirectory,
        NSAutosavedInformationDirectory = 11,
        NSDesktopDirectory = 12,
        NSCachesDirectory = 13,
        NSApplicationSupportDirectory = 14,
        NSDownloadsDirectory = 15,
        NSInputMethodsDirectory = 16,
        NSMoviesDirectory = 17,
        NSMusicDirectory = 18,
        NSPicturesDirectory = 19,
        NSPrinterDescriptionDirectory = 20,
        NSSharedPublicDirectory = 21,
        NSPreferencePanesDirectory = 22,
        NSApplicationScriptsDirectory = 23,
        NSItemReplacementDirectory = 99,
        NSAllApplicationsDirectory = 100,
        NSAllLibrariesDirectory = 101,
        NSTrashDirectory = 102
    };
    typedef unsigned long SearchPathDirectory;

    enum {
        NSUserDomainMask = 1,       // user's home directory --- place to install user's personal items (~)
        NSLocalDomainMask = 2,      // local to the current machine --- place to install items available to everyone on this machine (/Library)
        NSNetworkDomainMask = 4,    // publically available location in the local area network --- place to install items available on the network (/Network)
        NSSystemDomainMask = 8,     // provided by Apple, unmodifiable (/System)
        NSAllDomainsMask = 0x0ffff  // all domains: all of the above and future items
    };
    typedef unsigned long SearchPathDomainMask;

    class FolderManager {
        public:

        FolderManager();
        ~FolderManager();

        const char *pathForDirectory(SearchPathDirectory directory, SearchPathDomainMask domainMask);
        const char *pathForDirectoryAppropriateForItemAtPath(SearchPathDirectory directory, SearchPathDomainMask domainMask, const char *itemPath, bool create = false);

        private:
            void *m_autoreleasePool;
    };
};

FolderManager.mm(注意文件扩展名)

#include "FolderManager.h"
#import <Foundation/Foundation.h>

using namespace fm;

FolderManager::FolderManager() {
    m_autoreleasePool = [[NSAutoreleasePool alloc] init];
}

FolderManager::~FolderManager() {
    [(NSAutoreleasePool *)m_autoreleasePool release];
}

const char * FolderManager::pathForDirectory(SearchPathDirectory directory, SearchPathDomainMask domainMask) {
    NSFileManager *fileManager = [NSFileManager defaultManager];
    NSArray *URLs = [fileManager URLsForDirectory:(NSSearchPathDirectory)directory inDomains:domainMask];
    if (URLs.count == 0) return NULL;

    NSURL *URL = [URLs objectAtIndex:0];
    NSString *path = URL.path;

    // `fileSystemRepresentation` on an `NSString` gives a path suitable for POSIX APIs
    return path.fileSystemRepresentation;
}

const char * FolderManager::pathForDirectoryAppropriateForItemAtPath(SearchPathDirectory directory,
 SearchPathDomainMask domainMask, const char *itemPath, bool create) {

    NSFileManager *fileManager = [NSFileManager defaultManager];
    NSString *nsPath = [fileManager stringWithFileSystemRepresentation:itemPath length:strlen(itemPath)];
    NSURL *itemURL = (nsPath ? [NSURL fileURLWithPath:nsPath] : nil);

    NSURL *URL = [fileManager URLForDirectory:(NSSearchPathDirectory)directory
                       inDomain:domainMask
              appropriateForURL:itemURL
                         create:create error:NULL];
    return URL.path.fileSystemRepresentation;
}

请注意，这应该在没有启用自动引用计数的情况下编译(或者至少，这就是我使用它的方式；它可能也适用于 ARC，但我还没有测试过)。在构造函数和析构函数中分别创建和释放 NSAutoreleasePool 很重要，否则，您可能会在控制台中收到内存泄漏和警告(除非 NSAutoreleasePool 具有已在别处为您创建)**。

要使用它，像这样:

int main(int argc, const char * argv[]) {

    char *folderPath = NULL;
    FolderManager folderManager;
    folderPath = (char *)folderManager.pathForDirectory(NSApplicationSupportDirectory, NSUserDomainMask);
    printf("folderPath == %s\n", folderPath);

    folderPath = (char *)folderManager.pathForDirectory(NSApplicationSupportDirectory, NSLocalDomainMask);
    printf("folderPath == %s\n", folderPath);

    folderPath = (char *)folderManager.pathForDirectory(NSTrashDirectory, NSAllDomainsMask);
    printf("folderPath == %s\n", folderPath);

    if (argc > 1) {
        folderPath = (char *)folderManager.pathForDirectoryAppropriateForItemAtPath(NSTrashDirectory, NSAllDomainsMask, argv[1]);
        printf("folderPath == %s\n", folderPath);

        folderPath = (char *)folderManager.pathForDirectoryAppropriateForItemAtPath(NSItemReplacementDirectory, NSUserDomainMask, argv[1], true);
        printf("folderPath == %s\n", folderPath);
    }

    return 0;
}

当我在我的机器上运行它时，将参数传递给 /Volumes/Untitled3/folder/testFile.chm，它将输出以下内容:

folderPath == /Users/mdouma46/Library/Application Support
folderPath == /Library/Application Support
folderPath == /Users/mdouma46/.Trash
folderPath == /Volumes/Untitled 3/.Trashes/501
folderPath == /Volumes/Untitled 3/.TemporaryItems/folders.501/TemporaryItems/(A Document Being Saved By findFolder)

**关于关于 NSAutoreleasePool 重要性的内存管理注释:我在 OS X Yosemite、Xcode 7.2.1 中测试了它，注释掉了 NSAutoreleasePool<>，在我的一生中，我无法将任何错误记录到控制台，所以我不确定发生了什么。

我所期待的是我在 OS X 10.6 中的 Xcode 3.2.6 中编译它时得到的结果:

findFolder[300] *** __NSAutoreleaseNoPool(): Object 0x10010c6d0 of class NSCFArray autoreleased with no pool in place - just leaking
findFolder[300] *** __NSAutoreleaseNoPool(): Object 0x10010c820 of class NSCFString autoreleased with no pool in place - just leaking
findFolder[300] *** __NSAutoreleaseNoPool(): Object 0x100111540 of class NSCFString autoreleased with no pool in place - just leaking
findFolder[300] *** __NSAutoreleaseNoPool(): Object 0x100111710 of class NSPathStore2 autoreleased with no pool in place - just leaking
findFolder[300] *** __NSAutoreleaseNoPool(): Object 0x100111770 of class NSPathStore2 autoreleased with no pool in place - just leaking
findFolder[300] *** __NSAutoreleaseNoPool(): Object 0x100111a20 of class NSCFArray autoreleased with no pool in place - just leaking
findFolder[300] *** __NSAutoreleaseNoPool(): Object 0x100111a60 of class NSCFArray autoreleased with no pool in place - just leaking
findFolder[300] *** __NSAutoreleaseNoPool(): Object 0x100111d10 of class NSCFString autoreleased with no pool in place - just leaking
findFolder[300] *** __NSAutoreleaseNoPool(): Object 0x100111ac0 of class NSURL autoreleased with no pool in place - just leaking
findFolder[300] *** __NSAutoreleaseNoPool(): Object 0x100111c20 of class NSCFArray autoreleased with no pool in place - just leaking
findFolder[300] *** __NSAutoreleaseNoPool(): Object 0x100111de0 of class NSCFString autoreleased with no pool in place - just leaking
findFolder[300] *** __NSAutoreleaseNoPool(): Object 0x100111cb0 of class NSConcreteData autoreleased with no pool in place - just leaking
folderPath == /Users/mdouma46/Library/Application Support

发生这种情况是因为许多 Objective-C 调用返回自动释放的对象:NSFileManager 的 URLsForDirectory:inDomain: 返回一个自动释放的 NSURL 数组s。调用 NSURL 的 path 方法返回(创建)自动释放的 NSString(实际上是 NSPathStore2 私有(private)子类)，等等……

关于c++ - 使用 C++ 访问 OS X 上的标准目录，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/36634632/