我正在使用 delphi 在桌面上进行开发。我想用 ToastGeneric 类型通知创建 toast 通知 LToastFactory.CreateToastNotification(LXMLTemplate);

此外，我正在使用 xml，如 https://learn.microsoft.com/en-us/windows/uwp/controls-and-patterns/tiles-and-notifications-adaptive-interactive-toasts

我的问题是如何让 delphi 接受这个 xml，我还没有找到将该字符串转换为 Xml_Dom_IXmlDocument 类型的方法。

最佳答案

我遇到了同样的问题。

我的目标是从使用 toastGeneric 的 Delphi 创建一个 Toast 通知。但是，我找不到任何通过操作 xml 来执行此操作的任何语言的示例 - 所有示例都使用了似乎无法从 Delphi 访问的类。

我的解决方案是创建一个标准模板，然后用自定义模板所需的 xml 覆盖该标准模板中的 xml。下面是一些应该给你想法的 Delphi 代码。它是一个完整的控制台应用程序。此代码在 Delphi 10.2 Tokyo 下编译。早期版本可能需要进行一些调整。您会对 OverwriteToastTemplateXML 函数感兴趣。

我的代码基于 Marco Cantu 博客文章最后评论中引用的标准 toast 模板示例:http://blog.marcocantu.com/blog/2015-june-windows10-notifications-vcl-winrt.html

请注意我的 XML 中对“英雄”图像 jpg 文件的引用。为了让通知充分发挥作用，请确保您在 c:\notifications\hero.jpg 中有一个 jpg，或者在 xml 中注释掉该行。

除了将 XML 字符串转换为自定义 toast 模板外，该代码还将 toast 模板转换回字符串，这对于调试很有用 - 这就是 ToastTemplateToString 函数。这些是我对原始示例的主要功能修改。为了我自己的理解，我还更改了示例代码的结构，以便变量范围以及每行代码与其他代码的关系也更加明显。

让我知道这是否适合您 - 我发现 Toast 通知是 Delphi 的一项艰巨工作!

干杯

史蒂夫

program ConsoleNotifier;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils,

  // Required to create the Toast Notification
  WinAPI.WinRT,
  WinAPI.DataRT,
  WinAPI.UI.Notifications,
  WinAPI.ActiveX,
  WinAPI.CommonTypes,

  // Required for creating the Desktop Shell Link
  WinAPI.PropKey,
  WinAPI.PropSys,
  WinAPI.ShlObj,
  System.Win.ComObj,
  Windows
  ;

function CreateDesktopShellLink(const TargetName: string): Boolean;

  function GetStartMenuFolder: string;
  var
    Buffer: array [0 .. MAX_PATH - 1] of Char;
  begin
    Result := '';
    GetEnvironmentVariable(PChar('APPDATA'), Buffer, MAX_PATH - 1);
    Result := Buffer + '\Microsoft\Windows\Start Menu\Programs\Desktop Delphi Toasts App.lnk';
  end;

var
  IObject: IUnknown;
  ISLink: IShellLink;
  IPFile: IPersistFile;
  LinkName: string;

  LStore: WinAPI.PropSys.IPropertyStore;
  LValue: TPropVariant;
begin
  Result := False;

  IObject := CreateComObject(CLSID_ShellLink);
  ISLink := IObject as IShellLink;
  IPFile := IObject as IPersistFile;
  LStore := IObject as WinAPI.PropSys.IPropertyStore;

  with ISLink
  do begin
    SetPath(PChar( ParamStr(0) ));
  end;
  ISLink.SetArguments(PChar(''));

  if Succeeded(InitPropVariantFromStringAsVector(PWideChar('Delphi.DesktopNotification.Sample'), LValue))
  then begin
    if Succeeded(LStore.SetValue(PKEY_AppUserModel_ID, LValue))
    then LStore.Commit;
  end;

  LinkName := GetStartMenuFolder;

  if not FileExists(LinkName)
  then
    if IPFile.Save(PWideChar(LinkName), True) = S_OK
    then Result := True;
end;

function HStr( Value:String ): HString;
begin
  if NOT Succeeded(
    WindowsCreateString(PWideChar(Value), Length(Value), Result)
  )
  then raise Exception.CreateFmt('Unable to create HString for %s', [ Value ] );
end;

function ToastTemplateToString( Const Template:Xml_Dom_IXmlDocument ): String;

  function HStringToString(Src: HSTRING): String;
  var
    c: Cardinal;
  begin
    c := WindowsGetStringLen(Src);
    Result := WindowsGetStringRawBuffer(Src, @c);
  end;

begin
  Result := HStringToString(
    ( Template.DocumentElement as Xml_Dom_IXmlNodeSerializer ).GetXml
  );
end;

function GetFactory( Const Name:String; Const GUID:String ): IInspectable;
var
  FactoryHString : HString;
  FactoryGUID    : TGUID;
begin
  FactoryHString := HStr( Name );
  try
    FactoryGUID := TGUID.Create(GUID);

    if NOT Succeeded(
      RoGetActivationFactory(FactoryHString, FactoryGUID, Result)
    )
    then raise Exception.CreateFmt('Error creating factory: %s %s', [ Name, GUID ] );
  finally
    WindowsDeleteString( FactoryHString );
  end;
end;

procedure OverwriteToastTemplateXML( Const Template: Xml_Dom_IXmlDocument; Const XML:String );
var
  hXML: HSTRING;
begin
  hXML := HStr( XML );
  try
    (Template as Xml_Dom_IXmlDocumentIO).LoadXml( hXML );
  finally
    WindowsDeleteString( hXML );
  end;
end;

procedure SteveNotification( Const AppID:String; Const XML:String );
var
  ToastNotificationManagerStatics : IToastNotificationManagerStatics;
  ToastTemplate                   : Xml_Dom_IXmlDocument;
  LToastNotification              : IToastNotification;
  ToastNotificationManagerFactory : IInspectable;
  ToastNotificationFactory        : IInspectable;
  hAppID                          : HString;
begin
  ToastNotificationManagerFactory := GetFactory( sToastNotificationManager, '{50AC103F-D235-4598-BBEF-98FE4D1A3AD4}' );
  ToastNotificationManagerStatics := IToastNotificationManagerStatics(ToastNotificationManagerFactory);
  ToastTemplate := ToastNotificationManagerStatics.GetTemplateContent(ToastTemplateType.ToastText01);

  OverwriteToastTemplateXML( ToastTemplate, XML );

  WriteLn( 'XML: ', ToastTemplateToString( ToastTemplate ) );

  ToastNotificationFactory := GetFactory( SToastNotification, '{04124B20-82C6-4229-B109-FD9ED4662B53}' );

  LToastNotification := IToastNotificationFactory(ToastNotificationFactory).CreateToastNotification(ToastTemplate);

  hAppID := HStr( AppID );
  try
    ToastNotificationManagerStatics
    .CreateToastNotifier( hAppID )
    .Show(LToastNotification);
  finally
    WindowsDeleteString( hAppID );
  end;
end;

Const
  AppID = 'My Application ID';
  XML   = '<toast activationType="protocol" launch="http://www.ecutek.com" >'
        + '  <visual>'
        + '    <binding template="ToastGeneric">'
        + '      <text>Body Text ABC</text>'
        + '      <text>More Text</text>'
        + '      <image placement="hero" src="file:///c:\notifications\hero.jpg"/>'
        + '    </binding>'
        + '  </visual>'
        + '  <actions>'
        + '    <action content="Open Google" activationType="protocol" arguments="http://www.google.com" />'
        + '  </actions>'
        + '</toast>';

var
  c : char;
begin
  try
    if TOSVersion.Major < 10
    then raise Exception.Create('Windows 10 Required');

    RoInitialize(RO_INIT_MULTITHREADED);

    CreateDesktopShellLink( ParamStr(0) );

    SteveNotification( AppID, XML );

    // Wait for a KeyPress
    Read( c ); write( c );
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

关于windows - 如何使用 ToastGeneric 在 delphi 中创建 toast 通知，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/45856979/