jjzjj

windows - 修改for循环以在批处理脚本中不使用延迟扩展

coder 2024-06-20 原文

在我努力理解for..do循环语法和它们对%%变量的使用时。我已经经历了两个具体的例子/实现，其中一个for循环不使用DELAYEDEXPANSION，另一个循环使用DELAYEDEXPANSION符号。第一个for循环似乎与较旧的操作系统兼容，如WindowsXP，而第二个for循环示例则不兼容。
具体而言，第一个for循环示例取自此answer（与this相关），第二个for循环示例取自此answer。
两个示例的修改代码复制如下：
第一回路

for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%"
set "YYYY=%dt:~0,4%"
set "MM=%dt:~4,2%"
set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%"
set "Min=%dt:~10,2%"
set "Sec=%dt:~12,2%"
set "datestamp=%YYYY%%MM%%DD%"
set "timestamp=%HH%%Min%%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"

第二回路
SETLOCAL ENABLEDELAYEDEXPANSION
set "path_of_folder=C:\folderA\folderB"

for /f "skip=5 tokens=1,2,4 delims= " %%a in (
 'dir /ad /tc "%path_of_folder%\."') do IF "%%c"=="." (
  set "dt=%%a"
  set vara=%%a
  set varb=%%b
  echo !vara!, !varb!
  set day=!vara:~0,2!
  echo !day!
)

由于我一直在阅读和看到延迟扩展（或!符号）与旧的操作系统（如windows xp）不兼容的问题，我想看看如何编写第二个循环，如第一个循环；即不使用!。

最佳答案

我详细解释了aschipfl在他的评论中所写的内容。
这两个批处理文件也可以在windows 2000和windows xp上使用cmd.exe作为命令解释器。批处理文件不能在MS-DOS、Windows 95和Windows 98上使用非常有限的command.com作为命令解释器。
可以在命令提示窗口中使用参数/?执行命令，以获取此命令的帮助输出。当使用已启用的命令扩展编写帮助时，这意味着仅由基于Windows NT的Windows版本上的cmd.exe支持，而MS-DOS或使用command.com的Windows 9x不支持。这意味着，例如for /F或if /I或call :Subroutine在windows 9x上不可用，或者在显式禁用命令扩展的基于windows nt的windows上不可用。在Windows9x上，甚至不能使用"%~1"或"%~nx1"。
第一个批处理文件仅在for循环中执行1次命令，精确到1次：

set "dt=%%a"

以下所有其他命令在for循环完成后执行。换句话说，第一批文件中的for循环不使用命令块在for循环中运行多个命令。
每当Windows NT命令解释器检测到命令行上的命令块开始时，它会在第一次在此命令行上执行命令之前处理整个命令块。
这意味着对于第二批文件，在执行for命令之前，使用%Variable%的所有变量引用都已展开，然后使用上面为命令行定义的变量值执行命令块中的命令。这可以通过从批处理文件的第一行删除@echo off或将其更改为@echo ON并在命令提示符窗口中运行批处理文件来看到，因为现在可以看到哪些命令行分别是用(定义的整个命令块。)是在命令解释器预处理之后真正执行的。
因此，无论何时在命令块中定义或修改环境变量，并且在同一命令块中引用其值，都必须使用延迟扩展或使用解决方法。
一种解决方法如下所示：
setlocal EnableExtensions DisableDelayedExpansion
set "FolderPath=%SystemRoot%\System32"

for /F "skip=5 tokens=1,2,4 delims= " %%a in ('dir /AD /TC "%FolderPath%\."') do if "%%c"=="." (
    set "VarA=%%a"
    set "VarB=%%b"
    call echo %%VarA%%, %%VarB%%
    call set "Day=%%VarA:~0,2%%
    call echo %%Day%%
)

endlocal
pause

由于此批处理代码顶部没有@echo off，因此在执行批处理文件时可以看到此处发生的情况。每个%%在处理命令块时都被修改为仅%。命令行就是这样执行的。
call echo %VarA%, %VarB%
call set "Day=%VarA:~0,2%
call echo %Day%

命令调用用于第二次处理行的其余部分，以运行echo和set命令，环境变量引用替换为相应的值，而不替换或替换为字符串。
避免延迟扩展的另一个解决方法是使用子例程：
@echo off
setlocal EnableExtensions DisableDelayedExpansion
set "FolderPath=%SystemRoot%\System32"

for /F "skip=5 tokens=1,2,4 delims= " %%a in ('dir /AD /TC "%FolderPath%\."') do if "%%c"=="." call :ProcessCreationDate "%%a" "%%b"

endlocal
pause
goto :EOF

:ProcessCreationDate
echo %~1, %~2
set "Day=%~1"
set "Day=%Day:~0,2%
echo %Day%
goto :EOF

子例程类似于嵌入在当前批处理文件中的另一个批处理文件。
第一个goto :EOF避免了掉到子例程的代码中。
如果上面的行是批处理文件的最后一行，则不需要第二个goto :EOF。但是，如果以后像第二个子例程一样添加更多命令行，建议使用它。
第二个批处理文件用于获取创建指定文件夹的日期。可以在不使用延迟扩展和任何解决方法的情况下编写此批处理文件。
@echo off
setlocal EnableExtensions DisableDelayedExpansion
set "FolderPath=%SystemRoot%\System32"

for /F "skip=5 tokens=1,2,4 delims= " %%a in ('dir /ad /tc "%FolderPath%\." 2^>nul') do if "%%c"=="." set "CreationDate=%%a, %%b" & goto OutputDateAndDay

echo Failed to get creation date of "%FolderPath%"
endlocal
pause
goto :EOF

:OutputDateAndDay
echo %CreationDate%
set "Day=%CreationDate:~0,2%
echo %Day%
endlocal
pause

找到具有指定文件夹创建日期的相关行后，将为环境变量指定创建日期/时间，并使用goto命令退出for循环以继续在下面的标签上执行。有关&运算符的含义，请参见Single line with multiple commands using Windows batch file。
此解决方案优于所有其他方法，因为for循环只执行一次带有3个命令if、set和goto的单个命令行，这使得此解决方案最快。当由于目录根本不存在而无法确定目录的创建日期时，它会输出一条错误消息。
当然，在确定目录的创建日期并输出之后，还可以在其他解决方案上添加goto命令以退出for循环。不过，最后一个解决方案是最快的，在我看来，是完成这项任务的最佳方案。
顺便说一下：所有发布的批处理文件示例都在windows xp上进行了测试，并产生了预期的输出。

关于windows - 修改for循环以在批处理脚本中不使用延迟扩展，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/44953403/

windowsforcode34setbatch-filewindows-xpdelayedvariableexpansion

有关windows - 修改for循环以在批处理脚本中不使用延迟扩展的更多相关文章

  1. ruby - 如何使用 Nokogiri 的 xpath 和 at_xpath 方法 - 2

    我正在学习如何使用Nokogiri，根据这段代码我遇到了一些问题:require'rubygems'require'mechanize'post_agent=WWW::Mechanize.newpost_page=post_agent.get('http://www.vbulletin.org/forum/showthread.php?t=230708')puts"\nabsolutepathwithtbodygivesnil"putspost_page.parser.xpath('/html/body/div/div/div/div/div/table/tbody/tr/td/div

  2. ruby - 使用 RubyZip 生成 ZIP 文件时设置压缩级别 - 2

    我有一个Ruby程序，它使用rubyzip压缩XML文件的目录树。gem。我的问题是文件开始变得很重，我想提高压缩级别，因为压缩时间不是问题。我在rubyzipdocumentation中找不到一种为创建的ZIP文件指定压缩级别的方法。有人知道如何更改此设置吗？是否有另一个允许指定压缩级别的Ruby库？ 最佳答案 这是我通过查看ruby​​zip内部创建的代码。level=Zlib::BEST_COMPRESSIONZip::ZipOutputStream.open(zip_file)do|zip|Dir.glob("**/*")d

  3. ruby - 为什么我可以在 Ruby 中使用 Object#send 访问私有(private)/ protected 方法？ - 2

    类classAprivatedeffooputs:fooendpublicdefbarputs:barendprivatedefzimputs:zimendprotecteddefdibputs:dibendendA的实例a=A.new测试a.foorescueputs:faila.barrescueputs:faila.zimrescueputs:faila.dibrescueputs:faila.gazrescueputs:fail测试输出failbarfailfailfail.发送测试[:foo,:bar,:zim,:dib,:gaz].each{|m|a.send(m)resc

  4. ruby-on-rails - 使用 Ruby on Rails 进行自动化测试 - 最佳实践 - 2

    很好奇，就使用ruby​​onrails自动化单元测试而言，你们正在做什么？您是否创建了一个脚本来在cron中运行rake作业并将结果邮寄给您？git中的预提交Hook？只是手动调用？我完全理解测试，但想知道在错误发生之前捕获错误的最佳实践是什么。让我们理所当然地认为测试本身是完美无缺的，并且可以正常工作。下一步是什么以确保他们在正确的时间将可能有害的结果传达给您？ 最佳答案 不确定您到底想听什么，但是有几个级别的自动代码库控制:在处理某项功能时，您可以使用类似autotest的内容获得关于哪些有效，哪些无效的即时反馈。要确保您的提

  5. ruby - 在 Ruby 中使用匿名模块 - 2

    假设我做了一个模块如下:m=Module.newdoclassCendend三个问题:除了对m的引用之外，还有什么方法可以访问C和m中的其他内容？我可以在创建匿名模块后为其命名吗(就像我输入“module...”一样)？如何在使用完匿名模块后将其删除，使其定义的常量不再存在？ 最佳答案 三个答案:是的，使用ObjectSpace.此代码使c引用你的类(class)C不引用m:c=nilObjectSpace.each_object{|obj|c=objif(Class===objandobj.name=~/::C$/)}当然这取决于

  6. ruby - 使用 ruby​​ 和 savon 的 SOAP 服务 - 2

    我正在尝试使用ruby​​和Savon来使用网络服务。测试服务为http://www.webservicex.net/WS/WSDetails.aspx?WSID=9&CATID=2require'rubygems'require'savon'client=Savon::Client.new"http://www.webservicex.net/stockquote.asmx?WSDL"client.get_quotedo|soap|soap.body={:symbol=>"AAPL"}end返回SOAP异常。检查soap信封，在我看来soap请求没有正确的命名空间。任何人都可以建议我

  7. ruby - 在 Ruby 程序执行时阻止 Windows 7 PC 进入休眠状态 - 2

    我需要在客户计算机上运行Ruby应用程序。通常需要几天才能完成(复制大备份文件)。问题是如果启用sleep，它会中断应用程序。否则，计算机将持续运行数周，直到我下次访问为止。有什么方法可以防止执行期间休眠并让Windows在执行后休眠吗？欢迎任何疯狂的想法;-) 最佳答案 Here建议使用SetThreadExecutionStateWinAPI函数，使应用程序能够通知系统它正在使用中，从而防止系统在应用程序运行时进入休眠状态或关闭显示。像这样的东西:require'Win32API'ES_AWAYMODE_REQUIRED=0x0

  8. python - 如何使用 Ruby 或 Python 创建一系列高音调和低音调的蜂鸣声？ - 2

    关闭。这个问题是opinion-based.它目前不接受答案。想要改进这个问题？更新问题，以便editingthispost可以用事实和引用来回答它.关闭4年前。Improvethisquestion我想在固定时间创建一系列低音和高音调的哔哔声。例如:在150毫秒时发出高音调的蜂鸣声在151毫秒时发出低音调的蜂鸣声200毫秒时发出低音调的蜂鸣声250毫秒的高音调蜂鸣声有没有办法在Ruby或Python中做到这一点？我真的不在乎输出编码是什么(.wav、.mp3、.ogg等等)，但我确实想创建一个输出文件。

  9. ruby-on-rails - 'compass watch' 是如何工作的/它是如何与 rails 一起使用的 - 2

    我在我的项目目录中完成了compasscreate.和compassinitrails。几个问题:我已将我的.sass文件放在public/stylesheets中。这是放置它们的正确位置吗？当我运行compasswatch时，它不会自动编译这些.sass文件。我必须手动指定文件:compasswatchpublic/stylesheets/myfile.sass等。如何让它自动运行？文件ie.css、print.css和screen.css已放在stylesheets/compiled。如何在编译后不让它们重新出现的情况下删除它们？我自己编译的.sass文件编译成compiled/t

  10. ruby - 使用 ruby​​ 将 HTML 转换为纯文本并维护结构/格式 - 2

    我想将html转换为纯文本。不过，我不想只删除标签，我想智能地保留尽可能多的格式。为插入换行符标签，检测段落并格式化它们等。输入非常简单，通常是格式良好的html(不是整个文档，只是一堆内容，通常没有anchor或图像)。我可以将几个正则表达式放在一起，让我达到80%，但我认为可能有一些现有的解决方案更智能。 最佳答案 首先，不要尝试为此使用正则表达式。很有可能你会想出一个脆弱/脆弱的解决方案，它会随着HTML的变化而崩溃，或者很难管理和维护。您可以使用Nokogiri快速解析HTML并提取文本:require'nokogiri'h

随机推荐