使用 Mediaelementjs，我成功地实现了一个视频播放器，并触发一个结束事件，它会立即弹出一个 adobe 的 flash 记录器。在网站隐私设置面板中列出网站可以通过浏览器直接访问麦克风和摄像头。

问题:
有没有办法在用户允许访问麦克风和摄像头后触发某些功能，比如开始录制视频？

在用户允许使用闪光灯访问麦克风和摄像头后，我们能否以某种方式立即录制视频。

最佳答案

我的回答质量很差，因为很多年前我就对 Flash 失去了兴趣。最客气的说法是:我的Flash技术生疏了。 (生锈是指 Flash-8 ActionScript 2.0/Flash CS4 ActionScript 2.0 生锈级别)。真正的问题是什么 - 我当前的计算机上没有 Flash 测试环境。因此，这将是一个盲目的建议。当心错误。

但是，好的一面是，我确实有集成 Flash 和 Javascript 的经验。据我所知，其中一些内容仍然相关。

我知道的技术的简短列表:

Javascript 到 Flash:

1. Flash提供的ExternalInterface对象允许Javascript在Flash内部执行方法 - 这可以启动动画或返回数据。 缺点:ExternalInterface 可能会被安全设置或插件的错误实现所禁止。

2. document.getElementById('exampleMovie').SetVariable("someVariableName", "some text"); - 将其用作消息系统 - 添加将被监听的 Flash 计时器 - 做了一个变量改变

Flash 到 Javascript:

1. Flash 提供的ExternalInterface 对象允许Flash 从Javascript 执行功能。 缺点:ExternalInterface 可能会被安全设置或插件的错误实现所禁止。

2. getUrl( 'javascript:someJavascriptFunction( "a", "b", true );' ); 我不确定它是否出于安全原因被禁止但是 它可以工作。主要缺点是它是一种单向交互。

我认为使用外部接口(interface)是实现交互最合乎逻辑的方式。

是的，您可以使用单向交互 2. 和 2. 来构建通信协议(protocol) - 我什至可以想象那个系统......但那会有点太反常了 ^ ^。 + 我找不到任何关于浏览器支持“SetVariable”的数据。 + Stackoverflow 报告了 Firefox 中 SetVariable 的奇怪行为 SetVariable is not working in Firefox

这是外部接口(interface)的官方文档: http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/external/ExternalInterface.html

该页面有一个浏览器兼容性表。也许文档需要更新 - 没有谷歌浏览器的痕迹，在我看来这感觉很奇怪......

从概念上讲，您可以像这样使用外部接口(interface):

// HTML
// id must be equal to name here
// and shouldn't contain symbols . - + * / \
<object id="exampleFlash" name="exampleFlash" ... >
    ...
</object>

// Javascript:
document.getElementById('exampleFlash').methodExposedForJavascript('value')

// ActionScript in Flash:
import flash.external.ExternalInterface;
ExternalInterface.addCallback( "methodExposedForJavascript", someInternalFunction );
function someInternalFunction( msg ) {
    // do something with msg - for example output it to existing txt field:
    _root.txtExampleTxt.text = msg;
}

最相关的示例是该手册页上的最后一个 http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/external/ExternalInterface.html

关于如何编译复杂示例的简短说明:http://help.adobe.com/en_US/as3/dev/WS9b644acd4ebe5999-2734bf3c124372a52ff-8000.html

它们其实很简单。大多数感知到的复杂性来自于它们以编程方式生成 Flash 元素的事实 - 比如

// all that this code does - is creating simple TextField in your movie
import flash.text.TextField;
package  {
    public class ABC extends Sprite 
    {
        private var output:TextField;
        public function ABC() 
        {
            output = new TextField();
            output.y = 25;
            output.width = 450;
            addChild(output);
        }
    }
}

这样做是为了使示例更易于表达 - 但这与“使用您的 GUI 在第一帧中创建名为输出的文本字段”基本相同。

我将尝试删除该示例中不需要的任何内容。 注意“receivedFromJavaScript” - 这是一个将由 Javascript 触发的函数 - 你可以在里面添加 react 。

Flash部分:

package  {

    import flash.display.Sprite;
    import flash.events.*;
    import flash.external.ExternalInterface;
    import flash.text.TextField;
    import flash.utils.Timer;
    import flash.text.TextFieldType;
    import flash.text.TextFieldAutoSize;
    import flash.system.Security;

    public class ExternalInterfaceExample extends Sprite 
    {
        private var output:TextField;

        public function ExternalInterfaceExample() 
        {
            // constructor code
            Security.allowDomain("*");


            output = new TextField();
            output.y = 25;
            output.width = 450;
            output.height = 325;
            output.multiline = true;
            output.wordWrap = true;
            output.border = true;
            output.text = "Initializing...\n";
            addChild(output);


            if (ExternalInterface.available) {
                try {
                    output.appendText("Adding callback...\n");
                    ExternalInterface.addCallback("sendToActionScript", receivedFromJavaScript);
                    if (checkJavaScriptReady()) {
                        output.appendText("JavaScript is ready.\n");
                    } else {
                        output.appendText("JavaScript is not ready, creating timer.\n");
                        var readyTimer:Timer = new Timer(100, 0);
                        readyTimer.addEventListener(TimerEvent.TIMER, timerHandler);
                        readyTimer.start();
                    }
                } catch (error:SecurityError) {
                    output.appendText("A SecurityError occurred: " + error.message + "\n");
                } catch (error:Error) {
                    output.appendText("An Error occurred: " + error.message + "\n");
                }
            } else {
                output.appendText("External interface is not available for this container.");
            }
        }
        private function receivedFromJavaScript(value:String):void {
            output.appendText("JavaScript says: " + value + "\n");
        }
        private function checkJavaScriptReady():Boolean {
            var isReady:Boolean = ExternalInterface.call("isReady");
            return isReady;
        }
        private function timerHandler(event:TimerEvent):void {
            output.appendText("Checking JavaScript status...\n");
            var isReady:Boolean = checkJavaScriptReady();
            if (isReady) {
                output.appendText("JavaScript is ready.\n");
                output.appendText("ExternalInterface.objectID = " + ExternalInterface.objectID + "\n");
                Timer(event.target).stop();
            }
        }
    }
}

HTML:

<!DOCTYPE html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<title>ExternalInterfaceExample</title>
<script>
    var jsReady = false;
    function isReady() {
        return jsReady;
    }
    function pageInit() {
        jsReady = true;
        document.forms["form1"].output.value += "\n" + "JavaScript is ready.\n";
    }
    function sendToActionScript(value) {
        document.getElementById("ExternalInterfaceExample").sendToActionScript(value);
    }
</script>
</head>
<body onload="pageInit();">

<object id="ExternalInterfaceExample"  name="ExternalInterfaceExample" 
type="application/x-shockwave-flash" data="ExternalInterfaceExample.swf" width="550" height="400">
<param name="movie" value="ExternalInterfaceExample.swf"/>
<param name="quality" value="high"/>
<param name="allowscriptaccess" value="always"/>
<a href="http://www.adobe.com/go/getflash">
    <img src="http://www.adobe.com/images/shared/download_buttons/get_flash_player.gif" alt="Get Adobe Flash player"/>
</a>
</object>

    <form name="form1" onsubmit="return false;">
        <input type="text" name="input" value="" />
        <input type="button" value="Send" onclick="sendToActionScript(this.form.input.value);" /><br />
        <textarea cols="60" rows="20" name="output" readonly="true">Initializing...</textarea>
    </form>

</body>
</html>

关于javascript - 如何在视频停止使用 flash 播放后自动录制视频响应，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/35338763/