运行以下代码时

do line <- getLine
   putStrLn line

或者，

getLine >>= putStrLn

并且，之后

 getLine >>= putStrLn

进入

µ

遇到这个输出:

⠀

现在，我已经预先尝试了chcp 65001，这不起作用，stdin的编码是utf8。

没有 putStrLn 的检查显示:

 getLine
µ
'\NIL'

我的环境:
Windows 10 版本 10.0.17134 内部版本 17134
联想ideapad 510-15IKB
BIOS版本联想3JCN30WW
GHCi v 8.2.2

如何解决？

编辑:具体而言，以下操作序列会导致此问题:

1. 打开cmd
2. 输入chcp 65001
3. 输入ghci
4. 输入 getLine >>= putStrLn
5. 输入µ

但是，以下内容不会:

1. 搜索 ghci
2. 在 %PROGRAMS%\Haskell Platform\8.2.2\bin 打开 ghci.exe
3. 重复 4-5。

注意:%PROGRAMS% 不是真正的环境变量。

编辑:根据要求，GHC.IO.Encoding.getLocaleEncoding 的输出:

UTF-8

此外，System.IO.hGetEncoding stdin 的输出:

Just UTF-8

(使用 chcp 65001 时)

编辑:字符是 U+00B5。我使用的是德语键盘，系统语言环境德国，语言设置英语，键盘语言 ENG 和德语布局。

最佳答案

控制台输入/输出在 Windows 上完全损坏并且已经有一段时间了。这是跟踪 Windows 上与 IO 相关的所有问题的最重要问题单: https://ghc.haskell.org/trac/ghc/ticket/11394

我相信，这两张票最能描述您正在经历的行为:

• https://ghc.haskell.org/trac/ghc/ticket/10542
• https://ghc.haskell.org/trac/ghc/ticket/4471

目前唯一的解决方法是手动使用 Windows API 来处理控制台输出/输入，这本身就是一种痛苦。

编辑

所以，为了见鬼，我决定忍受一些痛苦。 :)

下面是代码的输出:

====
Input: µ
Output: µ
====

这绝不是一个完全正确或安全的解决方案，但它确实有效:

module Main where

import Control.Monad
import System.IO
import Foreign.Ptr
import Foreign.ForeignPtr
import Foreign.C.String
import Foreign.C.Types
import Foreign.Storable

import System.Win32
import System.Win32.Types
import Graphics.Win32.Misc

foreign import ccall unsafe "windows.h WriteConsoleW"
  c_WriteConsoleW :: HANDLE -> LPWSTR -> DWORD -> LPDWORD -> LPVOID -> IO BOOL

foreign import ccall unsafe "windows.h ReadConsoleW"
  c_ReadConsoleW :: HANDLE -> LPWSTR -> DWORD -> LPDWORD -> LPVOID -> IO BOOL

-- | Read n characters from a handle, which should be a console stdin
hwGetStrN :: Int -> Handle -> IO String
hwGetStrN maxLen hdl = do
  withCWStringLen (Prelude.replicate maxLen '\NUL') $ \(cstr, len) -> do
    lpNumberOfCharsWrittenForeignPtr <- mallocForeignPtr
    withHandleToHANDLE hdl $ \winHANDLE ->
      withForeignPtr lpNumberOfCharsWrittenForeignPtr $ \lpNumberOfCharsRead -> do
        c_ReadConsoleW winHANDLE cstr (fromIntegral len) lpNumberOfCharsRead nullPtr
        numWritten <- peek lpNumberOfCharsRead
        peekCWStringLen (cstr, fromIntegral numWritten)

-- | Write a string to a handle, which should be a console stdout or stderr.
hwPutStr :: Handle -> String -> IO ()
hwPutStr hdl str = do
  void $ withCWStringLen str $ \(cstr, len) -> do
    lpNumberOfCharsWrittenForeignPtr <- mallocForeignPtr
    withHandleToHANDLE hdl $ \winHANDLE ->
      withForeignPtr lpNumberOfCharsWrittenForeignPtr $ \ lpNumberOfCharsWritten ->
      c_WriteConsoleW winHANDLE cstr (fromIntegral len) lpNumberOfCharsWritten nullPtr

main :: IO ()
main = do
  hwPutStr stdout "====\nInput: "
  str <- hwGetStrN 10 stdin
  hwPutStr stdout "Output: "
  hwPutStr stdout str
  hwPutStr stdout "====\n"

编辑 2

@dfeuer 要求我列出不安全、不正确或不完整的答案。我只真正在 Linux 上编写代码，所以我不是 Windows 程序员，但在我的脑海中浮现出在代码可以用于实际程序之前需要更改的事情:

• 最重要的部分是代码只能与控制台句柄一起工作，这可以由 GetConsoleMode 确定。 API 调用。
• 对于其他类型的句柄，上面的代码将不执行任何操作，例如。如果与管道或文件句柄一起使用，它们在编码方面有其自身的问题，但这是一个完全独立的问题。
• 未考虑 API 调用失败。因此，我们必须通过查看返回的 BOOL 来检查调用是否成功，以及何时不使用 GetLastError将错误报告给用户。
• 上面实现的功能非常有限，没有检查它们实际从缓冲区读取/写入了多少。因此 hwGetStrN 只能处理 n 个字符，因此需要递归调用才能获得类似于 hGetLine
的行为
• 进行所有健全性检查，例如。 DWORD 是 Word32，因此 fromIntegral len 调用容易出现整数溢出，这是不正确且不安全的。
• FFI 调用在 32 位操作系统上必须是 stdcall，而 x86_64 上必须是 ccall，因此需要一些 CPP

关于windows - 你如何让 getLine 接受 unicode 字符？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/51661192/