我需要做什么？ 我需要根据 XSD 文件(传递文件路径/位置)验证 XML 文件(传递文件路径/位置)。我需要检查它是否格式正确，没有非法字符，并且它具有 XSD 中定义的所有标签，即没有丢失标签。它匹配 xsd 中定义的数据类型。完成后，我需要解析 xml 文件以获取数据并将其存储在数据库中。

有问题吗？ 1) 将 XmlReaderSetttings 与 XmlDocument 结合使用，将 XmlReader 与 Validate 方法结合使用是否可以帮助我实现所需的目标？任何人都可以帮我处理示例代码吗？

2) 解析 xml 文件以获取特定标签的最佳方法是什么？

我是 VB.net 的新手，所以任何示例代码帮助都将不胜感激。谢谢!

最佳答案

是的，您走在正确的轨道上。可以使用 XmlDocument 或 XmlReader 验证 XML 文档(正如我稍后将描述的，您也可以使用 XDocument)。您选择哪一个取决于您的情况，但它们的工作原理相似。当他们发现文档有错误时，他们会调用 ValidationEventHandler 委托(delegate)。 XmlReader 通过 XmlReaderSettings 对象中的事件调用它，而 XmlDocument 通过作为参数传递给其 Validate 的委托(delegate)调用它 方法。这是一个可用于收集错误的简单类:

Public Class XmlValidationErrorBuilder
    Private _errors As New List(Of ValidationEventArgs)()

    Public Sub ValidationEventHandler(ByVal sender As Object, ByVal args As ValidationEventArgs)
        If args.Severity = XmlSeverityType.Error Then
            _errors.Add(args)
        End If
    End Sub

    Public Function GetErrors() As String
        If _errors.Count <> 0 Then
            Dim builder As New StringBuilder()
            builder.Append("The following ")
            builder.Append(_errors.Count.ToString())
            builder.AppendLine(" error(s) were found while validating the XML document against the XSD:")
            For Each i As ValidationEventArgs In _errors
                builder.Append("* ")
                builder.AppendLine(i.Message)
            Next
            Return builder.ToString()
        Else
            Return Nothing
        End If
    End Function
End Class

该类中的 ValidationEventHandler 方法与 ValidationEventHandler 委托(delegate)的签名匹配，因此您可以使用它从 XmlReader 或 XmlDocument。以下是如何将它与 XmlDocument 一起使用:

Public Function LoadValidatedXmlDocument(xmlFilePath As String, xsdFilePath As String) As XmlDocument
    Dim doc As New XmlDocument()
    doc.Load(xmlFilePath)
    doc.Schemas.Add(Nothing, xsdFilePath)
    Dim errorBuilder As New XmlValidationErrorBuilder()
    doc.Validate(New ValidationEventHandler(AddressOf errorBuilder.ValidationEventHandler))
    Dim errorsText As String = errorBuilder.GetErrors()
    If errorsText IsNot Nothing Then
        Throw New Exception(errorsText)
    End If
    Return doc
End Function

下面是如何将它与 XmlReader 一起使用:

Public Sub LoadXml(xmlFilePath As String, xsdFilePath As String) 
    Dim settings As New XmlReaderSettings()
    settings.Schemas.Add(Nothing, xsdFilePath)
    settings.ValidationType = ValidationType.Schema
    Dim errorBuilder As New XmlValidationErrorBuilder()
    AddHandler settings.ValidationEventHandler, New ValidationEventHandler(AddressOf errorBuilder.ValidationEventHandler)
    Dim reader As XmlReader = XmlReader.Create(xmlFilePath, settings)
    ' Read the document...
    Dim errorsText As String = errorBuilder.GetErrors()
    If errorsText IsNot Nothing Then
        ' Handle the errors
    End If
End Function

或者，您也可以使用较新的 XDocument 类。 XDocument 的实现方式与 XmlDocument 非常相似。 XDocument 有一个Validate 扩展方法，它再次接受一个ValidationEventHandler 委托(delegate)。这是一个例子:

Public Function LoadValidatedXDocument(xmlFilePath As String, xsdFilePath As String) As XDocument
    Dim doc As XDocument = XDocument.Load(xmlFilePath)
    Dim schemas As New XmlSchemaSet()
    schemas.Add(Nothing, xsdFilePath)
    Dim errorBuilder As New XmlValidationErrorBuilder()
    doc.Validate(schemas, New ValidationEventHandler(AddressOf errorBuilder.ValidationEventHandler))
    Dim errorsText As String = errorBuilder.GetErrors()
    If errorsText IsNot Nothing Then
        Throw New Exception(errorsText)
    End If
    Return doc
End Function

至于将数据从 XML 文档加载到数据库中，如果不知道 XML 文档的模式、数据库的模式、数据库的类型等，就不可能准确地说出如何做到这一点。我建议对读取 XML 数据和将数据写入数据库进行一些研究，看看你能走多远。如果您在遇到麻烦时有任何具体问题，我们会随时为您提供帮助:)

关于xml - VB.NET 根据 XSD 文件验证 XML 文件并通过 xml 进行解析，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/18467389/