如何排序<foo name="..."/>来自 $foo 的节点使用它们来自 $bar 的相应节点顺序？

部分解决方案(Mark Veenstra)

<xsl:for-each select="$list-resources">
    <xsl:apply-templates select="$building-resources[@name = current()/@name]">
        <xsl:with-param name="param" select="$some-value"/>
    </xsl:apply-templates>
</xsl:for-each>

如何获取每个 $building-resources 节点在整个排序节点集中的位置？

TL;DR 回答

• <xsl:sort/>有一个属性，@data-type , 以指定 @select 中的数据类型节点。 默认为“文本”。因为我比较数字，所以我必须设置 @data-type="number" .否则，当比较 9 和 10 时，文本比较失败。

• <xsl:sort select="count($bar[@name = current()/@name]/preceding-sibling::*)" data-type="number"/>

• 在 <xsl:sort/> , current()指当前排序的节点(不是指<xsl:template/>当前节点)

感谢 michael.hor257k

完整答案

代码

    <!-- Resource "instances" to order, using $list-resources -->
    <xsl:variable name="building-resources"
        select="document('building.xml')/building/resource"/>

    <result>
        <!-- Apply templates to the resource instances -->
        <xsl:apply-templates select="$building-resources">
            <!-- Sort using the nodes order from the resources list -->
            <!-- Don't forget the @data-type: we're comparing NUMBERS not TEXTS -->
            <xsl:sort
                select="count($list-resources[@name = current()/@name]/preceding-sibling::*)"
                data-type="number"/>
        </xsl:apply-templates>
    </result>
</xsl:template>

<!-- Template to apply for each resource of $building-resources -->
<xsl:template match="ressource">
    <!-- position() refers to the node position in $building-resources
    because we used $building-resources as @select value
    of the apply-templates -->
    <output position="{position()}">
        <xsl:value-of select="."/>
    </output>
</xsl:template>

输入

列表资源.xml

<resources>
    <resource name="wood"/>
    <resource name="stone"/>
    <resource name="gold"/>
</resources>

建筑资源.xml

<building>
    <resource name="stone"/>
    <resource name="gold"/>
    <resource name="stone"/>
    <resource name="wood"/>
    <resource name="wood"/>
</building>

输出

<result>
    <output position="1">wood</output>
    <output position="2">wood</output>
    <output position="3">stone</output>
    <output position="4">stone</output>
    <output position="5">gold</output>
</result>

原始问题

排序

我有两个 XML 文档:

资源列表( list-resources.xml ，如“类”列表):

<resources>
    <resource name="wood"/>
    <resource name="stone"/>
    <resource name="gold"/>
</resources>

以及建筑物内的资源( buildings.xml ，如“对象”列表):

<building>
    <resource name="stone"/>
    <resource name="gold"/>
    <resource name="stone"/>
    <resource name="wood"/>
    <resource name="wood"/>
</building>

我想订购 <resource/>来自 <building/> 的节点所以它匹配 <resource/>从 <resources/> 订购.这是所需的输出:

<result>
    <output position="1">wood</output>
    <output position="2">wood</output>
    <output position="3">stone</output>
    <output position="4">stone</output>
    <output position="5">gold</output>
</result>

为此，我在 XSL 中有两个节点集:

<xsl:variable name="building-resources" select="building/resource"/>
<xsl:variable name="list-resources" select="resources/resource"/>

我使用 XSL 应用模板来处理来自 $building-resources 的节点:

<xsl:apply-templates select="$building-resources">
    <xsl:with-param name="some-param" select="$variable-from-somewhere"/>
</xsl:apply-templates>

假设应用的模板没问题。我目前未排序的结果是:

<result>
    <output position="1">stone</output>
    <output position="2">gold</output>
    <output position="3">stone</output>
    <output position="4">wood</output>
    <output position="5">wood</output>
</result>

现在，我添加了一个 <xsl:sort/>从 $building-resources 中对我的节点进行排序的元素, 但我不知道在它的 @select 里面放什么...

<xsl:apply-templates select="$building-resources">
    <xsl:sort select="what-to-put-here"/>
    <xsl:with-param name="some-param" select="$variable-from-somewhere"/>
</xsl:apply-templates>

我尝试了以下 XPath 表达式:

count($list-ressources[@name = current()/@name]/preceding-sibling::*)

但是在这个 XPath 中，current()指代 <xsl:template/> 处理的节点其中 <xsl:apply-templates/>是。 所以，而不是 current() , 但这不起作用，结果没有正确排序。 我的意思是 “<xsl:sort/> 进程当前正在处理的节点” (编辑:这实际上正是 current() 所做的!) 在我的 XPath 括号 $list-resources[] 中.我该怎么做？

获取排序位置

由于我简化了代码，我忘记了一些东西......Mark Veenstra 的解决方案提出了一个问题。

在应用的模板(生成<output/>节点的模板)中，我使用position()获取应用模板的节点的位置:

<xsl:template match="resource">
    <xsl:variable name="position" select="position()"/>
    <output position="{$position}">
        <xsl:value-of select="@name"/>
    </output>
</xsl:template>

只要我只执行“一个”应用模板(因此应用模板内的 position() 保持节点在排序列表中的位置)，它就可以很好地工作。但是如果我应用 Mark 的解决方案(请注意 current() 中的 <xsl:sort/> 现在指的是来自 <xsl:for-each/> 的节点，也就是来自 $liste-resources 的节点):

<xsl:for-each select="$list-resources">
    <xsl:apply-templates select="$building-resources[@name = current()/@name]">
        <xsl:with-param name="param" select="$some-value"/>
    </xsl:apply-templates>
</xsl:for-each>

然后 position()在所应用的模板中指的是节点在部分节点集中的位置($building-resources[@name = current()/@name])。

如何解决？

最佳答案

关于排序问题，我建议:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/">
    <building>
        <xsl:apply-templates select="building/resource">
            <xsl:sort select="count(document('list-resources.xml')/resources/resource[@name = current()/@name]/preceding-sibling::resource)" data-type="number" order="ascending"/>
        </xsl:apply-templates>
    </building>
</xsl:template>

<xsl:template match="resource">
    <resource position="{position()}">
        <xsl:value-of select="@name"/>
    </resource>
</xsl:template>

</xsl:stylesheet>

应用于您的输入示例，返回:

<?xml version="1.0" encoding="UTF-8"?>
<building>
   <resource position="1">wood</resource>
   <resource position="2">wood</resource>
   <resource position="3">stone</resource>
   <resource position="4">stone</resource>
   <resource position="5">gold</resource>
</building>

我不确定其他问题是什么。

关于xml - 使用变量中的其他节点在 XSL 应用模板节点中排序 (XSLT 1.0)，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/24533105/