jjzjj

string - 基于文件名的批量移动，不带分隔符，仅字符串

coder 2024-06-09 原文

好的，Windows 7 Enterprise x64出现Windows批处理文件问题。我是一个基本的用户，对批处理文件的创建知之甚少。我已经修改了可以在网上找到的现有脚本以供使用。

我有一个软件将其输出转储到一个文件夹，该文件夹的文件名与项目标题，当前系统日期，当前系统时间和项目设置串联在一起。

每次保存项目时，它将以这种格式导出两个文件:

PROJECTTITLE_2016_10_07__09_45_11__A_B_C.iges
PROJECTTITLE_2016_10_07__09_45_11__A_B_C.step

A，B和C代表软件中用于项目的开关。这些名称可能存在或不存在，因为文件名可以是_R_F或_R_F_Z等。
“PROJECTTITLE”实际上可以是任何东西。这是我使用分隔符出现问题的地方。您可能具有以下所有文件名(使用来自用户的实际示例):
11475shacklebody_2016_10_07__09_45_11__R_F.iges
11475shacklebody_2016_10_07__09_45_11__R_F.step
test_EFMflow_2016_10_07__09_45_11__R_Z.iges
test_EFMflow_2016_10_07__09_45_11__R_Z.step
untitled16_2016_10_07__09_45_11__R.iges
untitled16_2016_10_07__09_45_11__R.step
#14drop_wire-edm_2016_10_07__09_45_11__R_F_Z.iges
#14drop_wire-edm_2016_10_07__09_45_11__R_F_Z.step
prooftestwithoutupperlandsimproved-4_2016_10_07__09_45_11.iges
prooftestwithoutupperlandsimproved-4_2016_10_07__09_45_11.step

我想要做的是将IGES和STEP文件从C驱动器的输出文件夹移动到名称基于“PROJECTTITLE”的网络驱动器上的新文件夹，并在需要时创建该文件夹。我已经安排了一个基于-delim的批处理任务，使其每晚运行，但是发现分隔符不足以供我使用。

尽管使用分隔符似乎很容易，但要查找第一个下划线，但我有一些项目的名称带有下划线，这会破坏文件夹的命名。由于分隔符仅适用于单个字符，而不适用于字符串，因此我一直在寻找批处理文件的示例，我可以适应我的使用，但没有运气发现与我想使用的不使用分隔符类似的东西。

看起来很简单，在文件名中搜索字符串“_2016”，并在“_2016”之前获取所有字符，然后创建一个新目录，并将包含这些字符的文件放置在该文件夹中。我不知道如何在没有分隔符的情况下执行此操作。

到目前为止，我所做的工作是使用定界符查找下划线，创建文件夹并移动到映射驱动器上的那些文件夹:
for /f "delims=_" %%V in ('dir /b /a-d C:\Output\*_*.iges') do (
 mkdir "I:\ENG\PARTS\%%V" 2>nul
 move "C:\Output\%%V_*.iges" "I:\ENG\PARTS\%%V" >NUL 2>nul
 move "C:\Output\%%V_*.step" "I:\ENG\PARTS\%%V" >NUL 2>nul
)

这是一个非常简单的批处理文件，但其标题下划线包含在内。

一些事情:

搜索_2016意味着该批处理文件需要每年维护。我们可以搜索系统％YEAR％还是以某种正则表达式搜索"_####_##_##_"从而摆脱搜索系统日期或特定年份的麻烦？

编辑:
尽管由于开关有用而并不理想，但我在软件中找到了一种方法，使其不导出文件名末尾的项目专用开关。因此，现在的导出将是:
PROJECTTITLE_2016_10_07__09_45_11.iges
PROJECTTITLE_2016_10_07__09_45_11.step

我知道我可以从右开始修剪21个字符，使用该名称创建一个文件夹，并在目录中搜索包含该修剪字符串的所有文件。

尽管开关完好无损，但是弄清楚如何搜索特定的字符串还是很不错的。我愿意学习，因此可以对我的代码进行所有解释。

双(最新)编辑:
首先，感谢大家的回答，非常感谢您的帮助。

文件名中的双下划线非常少见，但是确实有可能是由于输入错误造成的。我计划与此一起移动的文件量变得越来越成问题。该软件可以在100个用户计算机上运行，​​其中20个左右为重用户，每个计算机每天最多可以保存1000个文件。当用户运行模拟时，该软件将自动以增量方式保存。我正在尝试为他们提供一种协作方式，并通过网络查看彼此的仿真结果(我们积极鼓励他们使用)，并且它表明该软件经过硬编码后可以输出到C驱动器(“性能”如下)。供应商告诉我)。我正在考虑安排文件在其OU中的每台PC上每15分钟移动一次，而不是每夜移动一次，以实时查看它们的工作情况。

我探索的另一个选项是将每台计算机上的输出文件夹符号链接(symbolic link)到软件的文件夹网络驱动器，但是发现这确实不能解决用户的“组织”问题，就像项目在同一文件夹中运行一样。还有一个问题是不允许他们在没有VPN的情况下将项目保存到办公室之外，有些用户会这样做，然后在他们回到办公室时将其文件移到办公室。

谢谢您的帮助。

最佳答案

即使文件名包含cmd有毒字符(例如空格或%百分号等)，下一个批处理脚本也可以执行此工作。

@ECHO OFF
SETLOCAL EnableExtensions DisableDelayedExpansion

set "_fouts=C:\Output"           your setting
set "_fouts=D:\test\39924063"    my setting 

for /F %%G in ('wmic OS get localdatetime ^|find "."') do set "_fyear=%%G"

pushd "%_fouts%"
  set "_fyear=%_fyear:~0,4%"
  call :doDir
  set /A _fyear -= 1
  call :doDir
popd

ENDLOCAL
goto :eof

:doDir
rem debugging output echo(%_fyear%
for /f "delims=" %%V in ('
  dir /b /a-d "*_%_fyear%_*.iges" "*_%_fyear%_*.step" 2^>NUL') do (
    set "_fname=%%~nV"           filename without extesion
    set "_fexte=%%~xV"           extesion only
    call :doAll
)
goto :eof

:doAll
    call set "_ftail=%%_fname:*_%_fyear%_=%%"
    call set "_fproj=%%_fname:_%_fyear%_%_ftail%=%%"
    rem debugging output echo("%_fproj%" "%_fname%" "%_fexte%"
    ECHO mkdir "I:\ENG\PARTS\%_fproj%" 2>nul
    ECHO move "%_fname%%_fexte%" "I:\ENG\PARTS\%_fproj%\"
goto :eof

输出(请注意，仅出于调试目的，分别使用mkdir和move显示可操作的ECHO mkdir和ECHO move命令):
==> dir /B /S "D:\test\39924063" /S
D:\test\39924063\#14drop_wire-edm_2016_10_07__09_45_11__R_F_Z.iges
D:\test\39924063\#14drop_wire-edm_2016_10_07__09_45_11__R_F_Z.step
D:\test\39924063\%PROJECT TITLE_2016_10_07__09_45_11__A_B_C.iges
D:\test\39924063\%PROJECT TITLE_2016_10_07__09_45_11__A_B_C.step

==> D:\bat\SO\39924063.bat
mkdir "I:\ENG\PARTS\#14drop_wire-edm"
move "#14drop_wire-edm_2016_10_07__09_45_11__R_F_Z.iges" "I:\ENG\PARTS\#14drop_wire-edm\"
mkdir "I:\ENG\PARTS\%PROJECT TITLE"
move "%PROJECT TITLE_2016_10_07__09_45_11__A_B_C.iges" "I:\ENG\PARTS\%PROJECT TITLE\"
mkdir "I:\ENG\PARTS\#14drop_wire-edm"
move "#14drop_wire-edm_2016_10_07__09_45_11__R_F_Z.step" "I:\ENG\PARTS\#14drop_wire-edm\"
mkdir "I:\ENG\PARTS\%PROJECT TITLE"
move "%PROJECT TITLE_2016_10_07__09_45_11__A_B_C.step" "I:\ENG\PARTS\%PROJECT TITLE\"

==>

资源(必填，不完整):
  • (命令引用)An A-Z Index of the Windows CMD command line
  • (其他特殊性)Windows CMD Shell Command Line Syntax
  • (%~nV，%~xV等特殊页面)Command Line arguments (Parameters)
  • (set "_fyear=%_fyear:~0,4%"等)Extract part of a variable (substring)
  • (%variable:StrToFind=NewStr%等)Variable Edit/Replace

    • 关于string - 基于文件名的批量移动，不带分隔符，仅字符串，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/39924063/

    string基于34code2016windowsbatch-filecmddelimiter

    有关string - 基于文件名的批量移动，不带分隔符，仅字符串的更多相关文章

    1. ruby - 如何从 ruby​​ 中的字符串运行任意对象方法？ - 2

      总的来说，我对ruby​​还比较陌生，我正在为我正在创建的对象编写一些rspec测试用例。许多测试用例都非常基础，我只是想确保正确填充和返回值。我想知道是否有办法使用循环结构来执行此操作。不必为我要测试的每个方法都设置一个assertEquals。例如:describeitem,"TestingtheItem"doit"willhaveanullvaluetostart"doitem=Item.new#HereIcoulddotheitem.name.shouldbe_nil#thenIcoulddoitem.category.shouldbe_nilendend但我想要一些方法来使用

    2. Ruby 解析字符串 - 2

      我有一个字符串input="maybe(thisis|thatwas)some((nice|ugly)(day|night)|(strange(weather|time)))"Ruby中解析该字符串的最佳方法是什么？我的意思是脚本应该能够像这样构建句子:maybethisissomeuglynightmaybethatwassomenicenightmaybethiswassomestrangetime等等，你明白了......我应该一个字符一个字符地读取字符串并构建一个带有堆栈的状态机来存储括号值以供以后计算，还是有更好的方法？也许为此目的准备了一个开箱即用的库？

    3. ruby - 使用 RubyZip 生成 ZIP 文件时设置压缩级别 - 2

      我有一个Ruby程序，它使用rubyzip压缩XML文件的目录树。gem。我的问题是文件开始变得很重，我想提高压缩级别，因为压缩时间不是问题。我在rubyzipdocumentation中找不到一种为创建的ZIP文件指定压缩级别的方法。有人知道如何更改此设置吗？是否有另一个允许指定压缩级别的Ruby库？ 最佳答案 这是我通过查看ruby​​zip内部创建的代码。level=Zlib::BEST_COMPRESSIONZip::ZipOutputStream.open(zip_file)do|zip|Dir.glob("**/*")d

    4. ruby - 其他文件中的 Rake 任务 - 2

      我试图在一个项目中使用rake，如果我把所有东西都放到Rakefile中，它会很大并且很难读取/找到东西，所以我试着将每个命名空间放在lib/rake中它自己的文件中，我添加了这个到我的rake文件的顶部:Dir['#{File.dirname(__FILE__)}/lib/rake/*.rake'].map{|f|requiref}它加载文件没问题，但没有任务。我现在只有一个.rake文件作为测试，名为“servers.rake”，它看起来像这样:namespace:serverdotask:testdoputs"test"endend所以当我运行rakeserver:testid时

    5. ruby-on-rails - 在 Rails 中将文件大小字符串转换为等效千字节 - 2

      我的目标是转换表单输入，例如“100兆字节”或“1GB”，并将其转换为我可以存储在数据库中的文件大小(以千字节为单位)。目前，我有这个:defquota_convert@regex=/([0-9]+)(.*)s/@sizes=%w{kilobytemegabytegigabyte}m=self.quota.match(@regex)if@sizes.include?m[2]eval("self.quota=#{m[1]}.#{m[2]}")endend这有效，但前提是输入是倍数(“gigabytes”，而不是“gigabyte”)并且由于使用了eval看起来疯狂不安全。所以，功能正常，

    6. ruby-on-rails - unicode 字符串的长度 - 2

      在我的Rails(2.3，Ruby1.8.7)应用程序中，我需要将字符串截断到一定长度。该字符串是unicode，在控制台中运行测试时，例如'א'.length，我意识到返回了双倍长度。我想要一个与编码无关的长度，以便对unicode字符串或latin1编码字符串进行相同的截断。我已经了解了Ruby的大部分unicode资料，但仍然有些一头雾水。应该如何解决这个问题？ 最佳答案 Rails有一个返回多字节字符的mb_chars方法。试试unicode_string.mb_chars.slice(0,50)

    7. ruby-on-rails - Rails 3 中的多个路由文件 - 2

      Rails2.3可以选择随时使用RouteSet#add_configuration_file添加更多路由。是否可以在Rails3项目中做同样的事情？ 最佳答案 在config/application.rb中:config.paths.config.routes在Rails3.2(也可能是Rails3.1)中，使用:config.paths["config/routes"] 关于ruby-on-rails-Rails3中的多个路由文件，我们在StackOverflow上找到一个类似的问题

    8. ruby - 将差异补丁应用于字符串/文件 - 2

      对于具有离线功能的智能手机应用程序，我正在为Xml文件创建单向文本同步。我希望我的服务器将增量/差异(例如GNU差异补丁)发送到目标设备。这是计划:Time=0Server:hasversion_1ofXmlfile(~800kiB)Client:hasversion_1ofXmlfile(~800kiB)Time=1Server:hasversion_1andversion_2ofXmlfile(each~800kiB)computesdeltaoftheseversions(=patch)(~10kiB)sendspatchtoClient(~10kiBtransferred)Cl

    9. ruby-on-rails - Rails 常用字符串(用于通知和错误信息等) - 2

      大约一年前，我决定确保每个包含非唯一文本的Flash通知都将从模块中的方法中获取文本。我这样做的最初原因是为了避免一遍又一遍地输入相同的字符串。如果我想更改措辞，我可以在一个地方轻松完成，而且一遍又一遍地重复同一件事而出现拼写错误的可能性也会降低。我最终得到的是这样的:moduleMessagesdefformat_error_messages(errors)errors.map{|attribute,message|"Error:#{attribute.to_s.titleize}#{message}."}enddeferror_message_could_not_find(obje

    10. ruby - 如何将脚本文件的末尾读取为数据文件(Perl 或任何其他语言) - 2

      我正在寻找执行以下操作的正确语法(在Perl、Shell或Ruby中):#variabletoaccessthedatalinesappendedasafileEND_OF_SCRIPT_MARKERrawdatastartshereanditcontinues. 最佳答案 Perl用__DATA__做这个:#!/usr/bin/perlusestrict;usewarnings;while(){print;}__DATA__Texttoprintgoeshere 关于ruby-如何将脚

    随机推荐