这是我第一次尝试使用 VBA 解析 XML 文件，所以我可能遗漏了一些显而易见的东西； 我已经可以打印这个了:

<values>
    <value code="1">A</value>
    <value code="2">B</value>
    <value code="3">C</value>
</values>

使用此代码行:

Debug.Print Variable.SelectSingleNode("values").XML

，其中 values 是其父节点 Variable

但我不知道如何遍历 values 的子级，并打印“1A”、“2B”、“3C”对

据我所知，this question使用根的第一个 child ，而我的目标是更深入地了解多层次结构。

最佳答案

在这里，我们可以看到如何使用 MSXML6.0 库为您的特定示例解析 XML。要使用此示例，您需要在 VBA 项目中添加对 MSXML6.0 的引用。

我建议您特别注意 XPath 变量“//value”和诸如 .getNamedItem("code") 之类的选择器——您需要熟悉其中的更多内容才能成为精通 XML 解析。幸运的是，其中很多都传递到 HTML 解析中，因此这是一项有用的技能!

在这种情况下，我选择了所有值节点。遍历它们就像根据节点数组的长度执行 for 循环并使用 .item(i) 调用一样简单。

Option Explicit
Sub test()
    Dim strXml As String
    strXml = "<values><value code=""1"">A</value><value code=""2"">B</value><value code=""3"">C</value></values>"

    Dim objXML As MSXML2.DOMDocument60
    Set objXML = New MSXML2.DOMDocument60

    If Not objXML.LoadXML(strXml) Then  'strXML is the string with XML'
        Err.Raise objXML.parseError.ErrorCode, , objXML.parseError.reason
    End If

    Dim entry_point As IXMLDOMNode
    Set entry_point = objXML

    Dim myNodes As IXMLDOMNodeList
    Dim myElement As IXMLDOMElement
    Dim myNode As IXMLDOMNode
    Dim nNode As Integer
    Set myNodes = entry_point.SelectNodes("//value")
    If myNodes.Length > 0 Then
        For nNode = 0 To myNodes.Length
            Set myNode = myNodes(nNode) ' Get the first node.
            If myNode Is Nothing Then
            Else
                Debug.Print myNode.Text
                Debug.Print myNode.Attributes.getNamedItem("code").Text
            End If
        Next nNode
    Else
        Debug.Print "No nodes found."
    End If

End Sub

这是另一种情况，我选择所有 VALUES 节点，然后遍历每个 VALUES 节点的子节点(假设所有值节点都只有值子节点)。

Option Explicit
Sub test()
    Dim strXml As String
    strXml = "<values><value code=""1"">A</value><value code=""2"">B</value><value code=""3"">C</value></values>"

    Dim objXML As MSXML2.DOMDocument60
    Set objXML = New MSXML2.DOMDocument60

    If Not objXML.LoadXML(strXml) Then  'strXML is the string with XML'
        Err.Raise objXML.parseError.ErrorCode, , objXML.parseError.reason
    End If

    Dim entry_point As IXMLDOMNode
    Set entry_point = objXML

    Dim myNodes As IXMLDOMNodeList
    Dim myChildNodes As IXMLDOMNodeList
    Dim myElement As IXMLDOMElement
    Dim myNode As IXMLDOMNode
    Dim myChildNode As IXMLDOMNode
    Dim nNode As Integer
    Dim nChildNode As Integer
    Set myNodes = entry_point.SelectNodes("//values")
    If myNodes.Length > 0 Then
        For nNode = 0 To myNodes.Length - 1
            Set myNode = myNodes(nNode)
            If myNode Is Nothing Then
            Else
                Set myChildNodes = myNode.ChildNodes ' Get the children of the first node.
                For nChildNode = 0 To myChildNodes.Length - 1
                    Debug.Print myChildNodes(nChildNode).Text
                    Debug.Print myChildNodes(nChildNode).Attributes.getNamedItem("code").Text
                Next nChildNode
            End If
        Next nNode
    Else
        Debug.Print "No nodes found."
    End If

End Sub

关于xml - VBA XML 解析——遍历子节点，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/40658630/