我有一个问题可以归结为找到一种将三角矩阵映射到跳过对角线的 vector 的方法。

基本上我需要使用 Gecode 库翻译这段 C++ 代码

// implied constraints
for (int k=0, i=0; i<n-1; i++)
  for (int j=i+1; j<n; j++, k++)
    rel(*this, d[k], IRT_GQ, (j-i)*(j-i+1)/2);

进入这个 MiniZinc(功能)代码

constraint
   forall ( i in 1..m-1 , j in i+1..m )
      ( (differences[?]) >=  (floor(int2float(( j-i )*( j-i+1 )) / int2float(2)) ));

我需要找出differences[?]中的索引。

MiniZinc 是一种函数/数学语言，没有合适的 for 循环。 因此，我必须将那些触及上三角矩阵所有且仅触及上三角矩阵单元格的索引 i 和 j 映射到 k，将这些单元格从 0 到任何编号。

如果这是一个正则三角矩阵(不是)，一个解 like this会做

index = x + (y+1)*y/2

我正在处理的矩阵是一个正方形 n*n 矩阵，索引从 0 到 n-1，但最好为 n 提供更通用的解决方案*m 矩阵。

这是完整的 Minizinc 代码

% modified version of the file found at https://github.com/MiniZinc/minizinc-benchmarks/blob/master/golomb/golomb.mzn

include "alldifferent.mzn";

int: m;
int: n = m*m;
array[1..m] of var 0..n: mark;
array[int] of var 0..n: differences = [mark[j] - mark[i] | i in 1..m, j in i+1..m];

constraint mark[1] = 0;

constraint forall ( i in 1..m-1 ) ( mark[i] < mark[i+1] );

% this version of the constraint works
constraint forall ( i in 1..m-1 , j in i+1..m )
    ( (mark[j] - mark[i]) >= (floor(int2float(( j-i )*( j-i+1 )) / int2float(2))) );

%this version does not
%constraint forall ( i in 1..m-1, j in i+1..m )
%    ( (differences[(i-1) + ((j-2)*(j-1)) div 2]) >= (floor(int2float(( j-i )*( j-i+1 )) / int2float(2))) );

constraint alldifferent(differences);

constraint differences[1] < differences[(m*(m-1)) div 2];

solve :: int_search(mark, input_order, indomain, complete) minimize mark[m];

output ["golomb ", show(mark), "\n"];

谢谢。

最佳答案

小心点。您从该链接中找到的公式 index = x + (y+1)*y/2包括对角线条目，并且适用于下三角矩阵，我收集到的不是您想要的。您正在寻找的确切公式实际上是 index = x + ((y-1)y)/2 (参见:https://math.stackexchange.com/questions/646117/how-to-find-a-function-mapping-matrix-indices)。

再次注意，我给你的这个公式假设你的索引:x,y 是从零开始。您的 MiniZinc 代码正在使用 从 1 开始的索引 i,j (1 <= i=""><= m),="" 1=""><= j=""><= m))。对于从="" 1="" 开始的索引，公式为="">T(i,j) = i + ((j-2)(j-1))/2。所以你的代码应该是这样的:

constraint
   forall ( i in 1..m-1 , j in i+1..m )
      ((distances[(i + ((j-2)*(j-1)) div 2]) >= ...

请注意 (j-2)(j-1) 将始终是 2 的倍数，因此我们可以使用除数为 2 的整数除法(无需担心转换为/自 float )。

以上假定您使用的是正方形 m*m 矩阵。
要推广到 M*N 矩形矩阵，一个公式可以是:

其中 0 <= i="">< m,=""><= j="">< n="" [如果您再次需要索引从="" 1="" 开始，请在上面的公式中将="" i="" 替换为="" i-1，将="" j="" 替换为="" j-1]。这会触及上三角矩阵的所有单元格以及当="" n=""> M 时出现的正方形的“边上的额外 block ”。也就是说，它会触及所有单元格 (i,j) 使得 i < j="" 为="" 0=""><= i="">< m，0=""><= j=""><>

完整代码:

% original: https://github.com/MiniZinc/minizinc-benchmarks/blob/master/golomb/golomb.mzn

include "alldifferent.mzn";

int: m;
int: n = m*m;
array[1..m] of var 0..n: mark;
array[1..(m*(m-1)) div 2] of var 0..n: differences;

constraint mark[1] = 0;
constraint forall ( i in 1..m-1 ) ( mark[i] < mark[i+1] );
constraint alldifferent(differences);
constraint forall (i,j in 1..m where j > i)
    (differences[i + ((j-1)*(j-2)) div 2] = mark[j] - mark[i]);
constraint forall (i,j in 1..m where j > i)
    (differences[i + ((j-1)*(j-2)) div 2] >= (floor(int2float(( j-i )*( j-i+1 )) / int2float(2))));
constraint differences[1] < differences[(m*(m-1)) div 2];

solve :: int_search(mark, input_order, indomain, complete)
    minimize mark[m];

output ["golomb ", show(mark), "\n"];

下三角版本(采用之前的代码并在必要时交换 i 和 j):

% original: https://github.com/MiniZinc/minizinc-benchmarks/blob/master/golomb/golomb.mzn

include "alldifferent.mzn";

int: m;
int: n = m*m;
array[1..m] of var 0..n: mark;
array[1..(m*(m-1)) div 2] of var 0..n: differences;

constraint mark[1] = 0;
constraint forall ( i in 1..m-1 ) ( mark[i] < mark[i+1] );
constraint alldifferent(differences);
constraint forall (i,j in 1..m where i > j)
    (differences[j + ((i-1)*(i-2)) div 2] = mark[i] - mark[j]);
constraint forall (i,j in 1..m where i > j)
    (differences[j + ((i-1)*(i-2)) div 2] >= (floor(int2float(( i-j )*( i-j+1 )) / int2float(2))));
constraint differences[1] < differences[(m*(m-1)) div 2];

solve :: int_search(mark, input_order, indomain, complete)
    minimize mark[m];

output ["golomb ", show(mark), "\n"];

关于c++ - 在跳过对角线的 vector 上映射上三角矩阵，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/26402320/