ARM简单程序设计【嵌入式系统】
2023-4-6 20:26:54
以下内容源自《【嵌入式系统】》
仅供学习交流使用
新建工程xxx
芯片：ARM7 (Little Endian)
设置工程属性
Build结果必须是0Error的
如果是下图看配置是否正确
注意这个：
1.每一次修改代码就需要重写Build
2.READWRITE区变量初始化为0的解决
格式：
AREA xxx, CODE, READONLY ; 代码段的名字 symbol
ENTRY ; 程序的入口
CODE32
start
xxx
stop
MOV R0, #0x18
LDR R1, =0x20026
SWI 0x123456
AREA Data0, DATA, READONLY ;放到READONLY 注意段名字和下面不一样 Data0 Data
x DCD -25
AREA Data, DATA, READWRITE
y DCD 0
END
ARMex.s
例4- 1试编制一程序，完成10+3的操作
AREA ARMex, CODE, READONLY ; 代码段名ARMex
ENTRY ; 程序的入口
CODE 32
start
MOV R0, #10 ; 将立即数10存入寄存器R0
MOV R1, #3 ; 将立即数3存入寄存器R1
ADD R0, R0, R1 ; R0 = R0 + R1
stop
MOV R0, #0x18 ; 这三条指令是ADS调试环境特约
LDR R1, =0x20026 ;程序运行结束返回编译器调试环境
SWI 0x123456
END ; 结束
结果如下
(R0)=13
例4-2给定以下符号函数:
{ 1 x>0
y= { 0 x=0
{ -1 x<0
任意给定值，假定为-25，存放在x单元，函数值存放在y单元;要求根据x中的值来确定y的值。
symbol.s
AREA symbol, CODE, READONLY ; 代码段的名字 symbol
ENTRY ; 程序的入口
CODE32
start
LDR R0, =x ; 加载数据段中的变量x地址，存入R0
LDR R1, =y ; 加载数据段中的变量y地址，存入R1
LDR R2, [R0] ; 加载变量x的值，存入R2
compare
CMP R2, #0 ; 将R2的值与0作比较
BEQ ZERO ; 如果R2等于0，那么转向标号ZERO处
BGT PLUS ; 如果R2大于0，那么转向标号PLUS处
MOV R3, #-1 ; 否则，R2小于0，将-1存入R3中
B stop
ZERO
MOV R3, #0 ; R2等于0，将0存入R3中
B stop
PLUS
MOV R3, #1 ; R2大于0，将1存入R3中
stop
STR R3,[R1]
MOV R0, #0x18
LDR R1, =0x20026
SWI 0x123456
AREA Data0, DATA, READONLY
x DCD -25
AREA Data, DATA, READWRITE
y DCD 0
END
结果如下
R0=&x=0x00000048
R1=&y=0x40000000
R2=x=-25
R3=y=-1
例 4‑4 从x单元开始的30个连续字单元中存放有30个无符号数，从中找出最大者送入y单元中。
分析：
根据题意，把第一个数先送入Rx寄存器，将Rx中的数与后面的29个数逐个进行比较，如果Rx中的数较小，则将该较大的数送入Rx ；继续与余下的数据逐个比较。在比较过程中， Rx中始终保持较大的数，共计比较29次，则最终Rx中保留了最大数，最后把Rx中的数（最大者）送入y单元。
max.s
AREA max, CODE, READONLY ; 代码段的名字 max
ENTRY ; 程序的入口
CODE32
num EQU 29 ; 比较的次数
start
LDR R0, =x ; R0指向源数据块x
LDR R1, =y ; R1指向单元y
LDR R2, =num ; R2作为计数器
LDR R3, [R0] ; 将源数据块x中第一个数加载到R3中
compare
ADD R0, R0, #4 ; 每进行一次比较，将R0指针地址加4
LDR R4, [R0],#4 ; 依次将源数据块x中下一个数加载到R4中
CMP R3, R4 ; 比较R3和R4中数的大小
MOVCC R3, R4 ; 如果R3小于R4，则将较大的数送入R3中
SUBS R2, R2, #1 ; 计数器值减1
BNE compare ; 如果不为0，那么继续跳到compare执行
STREQ R3, [R1] ; 如果为0，那么循环比较结束，R3是最大的数
; 并且将R3中的数加载到R1指向的单元（即y）中
stop
MOV r0, #0x18
LDR r1, =0x20026
SWI 0x123456
AREA Data0, DATA, READONLY
x DCD 73,59,61,34,81,107,225,231,54,43
DCD 100,35,1,42,222,254,34,71,100,31
DCD 33,119,13,44,18,147,55,244,97,3
AREA Data, DATA, READWRITE
y DCD 0
END
说明
结果如下
R0=&x
R1=&y=0x40000000
R3=0x000000FE=254
例 4‑5 从自然数1开始累加，直到累加和大于1000为止，统计被累加的自然数的个数，并把统计的个数送入n单元，把累加和送入sum单元。
分析：
根据题意，被累加的自然数的个数事先未知，因此不能用计数方法控制循环。但题目中给定一个条件，即累加和大于1000则停止累加，因此，可以根据这一条件控制循环。我们用R3寄存器放累加和，用R4寄存器放每次取得的自然数，其中它的值也是统计自然数的个数。
SUM.s
AREA SUM, CODE, READONLY ; 代码段的名字 SUM
ENTRY ; 程序的入口
CODE32
start
LDR R0, =n ; 将数据段中自然数的个数n的地址加载到R0寄存器
LDR R1, =sum ; 将数据段中自然数的累加和sum的地址加载到R1寄存器
LDR R3, =0 ; R3存放自然数的累加和
LDR R4, =0 ; R4用于循环个数的统计/每次取得的自然数
LDR R5, =1000 ; R5用于循环结束的界限值
continue
ADD R4, R4, #1 ; 取下一个自然数
ADD R3, R3, R4 ; 累加自然数
CMP R3, R5 ; 比较累加和是否超过了1000
BCC continue ; 如果小于1000，那么跳到compare执行
STRCS R3, [R1] ; 如果大于1000，那么将累加和存储到R1所指向的单元中
STRCS R4, [R0] ; 如果大于1000，那么将已累加的自然数个数值存储
; 到R0所指向的单元中
stop
MOV r0, #0x18
LDR r1, =0x20026
SWI 0x123456
AREA Data, DATA, READWRITE
n DCD 0 ; 定义累加的自然数的个数
sum DCD 0 ; 定义自然数的累加和
END
结果如下
R0=&n=0x40000000
R1=&sum=0x40000004
R3=0x000004DB=1035
R4=0x0000002D=45
R5=0x000003E8=1000
Bibble.s
AREA Bibble, CODE, READONLY
ENTRY
start
;想实现数组拷贝 需要输入原数组 数组长度 输出目的数组 即可
;这里借用字符串拷贝 要求源数组最后加一个无效元素0 中间不能出现0
LDR R1, =src0 ; R1指向数据区的源字符串
LDR R0, =src ; R0指向数据区的目的字符串
BL strcopy ; 调用子程序strcopy，完成字符串拷贝
LDR R1,=src ; （右指针）R1起初指向src第一个单元
MOV R2, #0 ; 用于外层循环控制计数器，并初始化为0
LDR R4, num ; R4中是数据区中待排序数据个数
SUB R4, R4, #1 ;
ADD R1, R4,LSL #2 ;（右指针）R1指向src最后一个单元 R1=R1+R4*4,
outer ; 外层循环
LDR R0, =src ;（左指针）R0指向数据区src单元
inner ; 内层循环
LDR R5, [R0] ; 将R0所指向单元的数加载到R5中
LDR R6,[R0, #4] ; 将相邻单元的数加载到R6中
CMP R5, R6 ; 比较相邻两单元中的数
STRGT R6, [R0] ;如果前者大于后者，那么两个数交换
STRGT R5, [R0, #4] ; 内层循环修改、控制部分
ADD R0, R0, #4 ; 地址指针向下拨移4个字节
CMP R0, R1 ; 是否扫描了一遍
BNE inner ; 没有完成一遍，继续内循环
; 外层循环修改、控制部分，表示已经完成了一遍，
ADD R2, R2, #1 ; 外层循环控制计数器加1
SUB R1, R1, #4 ; 右指针R1向左指针方向移动4字节
CMP R2, R4 ; 是否全部扫描
BNE outer ; 没有完成全部扫描，继续外循环
stop
MOV R0, #0x18 ; 程序结束返回编译器调试环境
LDR R1, =0x20026
SWI 0x123456
strcopy
LDR R2, [R1], #4 ; 将R1指向的单元内容加载到R2中
STR R2, [R0], #4 ; 将R2中的数存储到R0指向的单元中
CMP R2, #0 ; 检查R0的值是否等于0
BNE strcopy ; 如果不等于0，那么转到strcopy处执行
MOV PC, LR ; 子程序返回
AREA BlockData0, DATA, READONLY
src0 DCD 18,4,2,35,3,20,1,23,12,21,0
num DCD 10
AREA BlockData, DATA, READWRITE
src DCD 18,4,2,35,3,20,1,23,12,21,0 ;Keil会把此数组初始化为0
END
说明
因为待排序数组直接放到READWITER，会有初始化为0的问题
所以就需把其放到READONLY下
但是，这就排不了序了
所以需要把其拷贝到一个READWITER下的数组，对其进行排序
这里我借用了字符串拷贝
真正的数组拷贝的设计：需要输入原数组 数组长度 输出目的数组 即可
另外
右指针的初始化
; （右指针）R1起初指向src第一个单元
LDR R1,=src ; 0x40000000
; R4中是数据区中待排序数据个数
LDR R4, num ;10
SUB R4, R4, #1 ;9
;（右指针）R1指向src最后一个单元 R1=R1+R4*4,用左移两位实现 一个元素占4个字节
ADD R1, R4,LSL #2 ;0x400000000+9*4=0x40000032
结果如下
1.完成数组拷贝
末尾的0是无效的
2.完成初始化
R0左指针->第一个
R1右指针->倒数的一个
3.第一遍循环
R0左指针->第一个
R1右指针->倒数的二个
倒数第一个，为最大的树
4.最终结果
R0左指针
R1右指针
R2=9 循环次数
R4=9 循环次数
R5,R6 是最后交换的两个数
StrCopy.s
AREA StrCopy, CODE, READONLY
ENTRY
CODE32
start
LDR R1, =srcstr ; R1指向数据区的源字符串
LDR R0, =dststr ; R0指向数据区的目的字符串
BL strcopy ; 调用子程序strcopy，完成字符串拷贝
stop
MOV R0, #0x18 ; 程序结束返回编译器调试环境
LDR R1, =0x20026
SWI 0x123456
strcopy
LDRB R2, [R1], #1 ; 将R1指向的单元内容加载到R2中
STRB R2, [R0], #1 ; 将R2中的数存储到R0指向的单元中
CMP R2, #0 ; 检查R0的值是否等于0
BNE strcopy ; 如果不等于0，那么转到strcopy处执行
MOV PC, LR ; 子程序返回
AREA Strings, DATA, READWRITE
srcstr DCB "First string - source",0 ; 源字符串
dststr DCB "Second string - destination",0 ; 目的字符串
END
结果如下
R0=&dststr=0x40000000
R1=&srcstr=0x00000038
Jump.s
AREA Jump, CODE, READONLY
num EQU 4 ; 函数地址表内容的个数
ENTRY
CODE32
start
LDR R0, =choice ; R0指向存储区的choice单元
LDR R0, [R0] ; 设置第一个参数：选择执行哪一个函数
MOV R1, #16 ; 设置第1个操作数
MOV R2, #2 ; 设置第2个操作数
BL arithfunc ; 调用子程序arithfunc
stop
MOV R0, #0x18 ; 程序结束返回编译器调试环境
LDR R1, =0x20026
SWI 0x123456
arithfunc
CMP R0, #num ; 比较R0的值是否超过函数地址表的个数
MOVHS PC, LR ; 如果大于，那么就返回到标号stop处
ADR R3, JumpTable ; 将函数地址表的地址作为基地址
LDR PC, [R3, R0, LSL #2] ; 根据R0参数进入对应的子程序
JumpTable ; 函数地址表的入口基地址
DCD DoAdd ; 加法子程序
DCD DoSub ; 减法子程序
DCD DoMul ; 乘法子程序
DCD DoDiv ; 除法子程序
DoAdd
ADD R0, R1, R2 ; R0 = R1 + R2
MOV PC, LR ; 返回
DoSub
SUB R0, R1, R2 ; R0 = R1 - R2
MOV PC, LR ; 返回
DoMul
MOV R0, R1, LSL R2 ; R0 = R1 << R2
MOV PC, LR ; 返回
DoDiv
MOV R0, R1, LSR R2 ; R0 = R1 >> R2
MOV PC, LR ; 返回
AREA NUM, DATA, READWRITE
choice DCD 3 ; 0：表示选择加法子程序 1：表示选择减法子程序
; 2：表示选择乘法子程序 3：表示选择除法子程序
END
说明
类似：函数指针的用法
ADR R3, JumpTable ; 将函数地址表的地址作为基地址
LDR PC, [R3, R0, LSL #2] ; 根据R0参数进入对应的子程序
结果如下
R0=16/1<<2=4
略
2023-4-6 22:29:06
2023-4-11 19:17:12
祝大家逢考必过
点赞收藏关注哦
我需要在客户计算机上运行Ruby应用程序。通常需要几天才能完成(复制大备份文件)。问题是如果启用sleep，它会中断应用程序。否则，计算机将持续运行数周，直到我下次访问为止。有什么方法可以防止执行期间休眠并让Windows在执行后休眠吗？欢迎任何疯狂的想法;-) 最佳答案 Here建议使用SetThreadExecutionStateWinAPI函数，使应用程序能够通知系统它正在使用中，从而防止系统在应用程序运行时进入休眠状态或关闭显示。像这样的东西:require'Win32API'ES_AWAYMODE_REQUIRED=0x0
我有一个模型:classItem项目有一个属性“商店”基于存储的值，我希望Item对象对特定方法具有不同的行为。Rails中是否有针对此的通用设计模式？如果方法中没有大的if-else语句，这是如何干净利落地完成的？ 最佳答案 通常通过Single-TableInheritance. 关于ruby-on-rails-Rails-子类化模型的设计模式是什么？，我们在StackOverflow上找到一个类似的问题： https://stackoverflow.co
Rackup通过Rack的默认处理程序成功运行任何Rack应用程序。例如:classRackAppdefcall(environment)['200',{'Content-Type'=>'text/html'},["Helloworld"]]endendrunRackApp.new但是当最后一行更改为使用Rack的内置CGI处理程序时，rackup给出“NoMethodErrorat/undefinedmethod`call'fornil:NilClass”:Rack::Handler::CGI.runRackApp.newRack的其他内置处理程序也提出了同样的反对意见。例如Rack
我想用ruby编写一个小的命令行实用程序并将其作为gem分发。我知道安装后，Guard、Sass和Thor等某些gem可以从命令行自行运行。为了让gem像二进制文件一样可用，我需要在我的gemspec中指定什么。 最佳答案 Gem::Specification.newdo|s|...s.executable='name_of_executable'...endhttp://docs.rubygems.org/read/chapter/20 关于ruby-在Ruby中编写命令行实用程序
我构建了两个需要相互通信和发送文件的Rails应用程序。例如，一个Rails应用程序会发送请求以查看其他应用程序数据库中的表。然后另一个应用程序将呈现该表的json并将其发回。我还希望一个应用程序将存储在其公共(public)目录中的文本文件发送到另一个应用程序的公共(public)目录。我从来没有做过这样的事情，所以我什至不知道从哪里开始。任何帮助，将不胜感激。谢谢! 最佳答案 无论Rails是什么，几乎所有Web应用程序都有您的要求，大多数现代Web应用程序都需要相互通信。但是有一个小小的理解需要你坚持下去，网站不应直接访问彼此
我尝试运行2.x应用程序。我使用rvm并为此应用程序设置其他版本的ruby:$rvmuseree-1.8.7-head我尝试运行服务器，然后出现很多错误:$script/serverNOTE:Gem.source_indexisdeprecated,useSpecification.Itwillberemovedonorafter2011-11-01.Gem.source_indexcalledfrom/Users/serg/rails_projects_terminal/work_proj/spohelp/config/../vendor/rails/railties/lib/r
刚入门rails，开始慢慢理解。有人可以解释或给我一些关于在application_controller中编码的好处或时间和原因的想法吗？有哪些用例。您如何为Rails应用程序使用应用程序Controller？我不想在那里放太多代码，因为据我了解，每个请求都会调用此Controller。这是真的？ 最佳答案 ApplicationController实际上是您应用程序中的每个其他Controller都将从中继承的类(尽管这不是强制性的)。我同意不要用太多代码弄乱它并保持干净整洁的态度，尽管在某些情况下ApplicationContr
我将应用程序升级到Rails4，一切正常。我可以登录并转到我的编辑页面。也更新了观点。使用标准View时，用户会更新。但是当我添加例如字段:name时，它不会在表单中更新。使用devise3.1.1和gem'protected_attributes'我需要在设备或数据库上运行某种更新命令吗？我也搜索过这个地方，找到了许多不同的解决方案，但没有一个会更新我的用户字段。我没有添加任何自定义字段。 最佳答案 如果您想允许额外的参数，您可以在ApplicationController中使用beforefilter，因为Rails4将参数
我是一个Rails初学者，但我想从我的RailsView(html.haml文件)中查看Ruby变量的内容。我试图在ruby中打印出变量(认为它会在终端中出现)，但没有得到任何结果。有什么建议吗？我知道Rails调试器，但更喜欢使用inspect来打印我的变量。 最佳答案 您可以在View中使用puts方法将信息输出到服务器控制台。您应该能够在View中的任何位置使用Haml执行以下操作:-puts@my_variable.inspect 关于ruby-on-rails-如何在我的R
有没有办法在这个简单的get方法中添加超时选项？我正在使用法拉第3.3。Faraday.get(url)四处寻找，我只能先发起连接后应用超时选项，然后应用超时选项。或者有什么简单的方法？这就是我现在正在做的:conn=Faraday.newresponse=conn.getdo|req|req.urlurlreq.options.timeout=2#2secondsend 最佳答案 试试这个:conn=Faraday.newdo|conn|conn.options.timeout=20endresponse=conn.get(url