尝试创建基于 XML 的 PDF 文件和使用 XMLSpy 的文件。

我正在尝试根据字段内容将一个字段分成两行。

例如，如果我的 varialbe = "John Doe AKA Johnny D"，我想这样查看它:

李四

强尼 D

我的问题是，即使使用网上的所有示例，我也无法使其正常工作。

这是我的代码:

     <xsl:value-of disable-output-escaping="yes" select="concat(substring-before(//MyField,'AKA'),$newline,substring-after(//MyField,'AKA'))" /> 
  </xsl:when>

基本上，每次我找到“AKA”字符串时，我都想将该字段分成两行。 所以我的代码，找到字符串，创建新变量但仍然显示在一行中。 我尝试使用各种技术创建一个带有空白行的变量，但仍然显示在一行中。

有什么想法吗？

最佳答案

参见 my answer here关于使用十六进制实体引用和 linefeed-treatment。

编辑

我从评论中获取了您的代码并将其放入示例 XSLT 样式表的模板中。我唯一改变的是:

1. 我将您的 newline 变量更改为 。
2. 我将 linefeed-treatment="preserve" 添加到您的 fo:block。

使用虚拟 XML 文件和 XSLT 样式表，我生成了一个 XSL-FO 文档，当使用 FOP 呈现时，在不同的行上生成“John Doe”和“Johnny D”。

这是 XML 文件:

<doc>
  <MyField>John Doe AKA Johnny D</MyField>
</doc>

这是 XSLT 样式表:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="/">
    <fo:root>
      <fo:layout-master-set>
        <fo:simple-page-master master-name="my-page" page-width="8.5in" page-height="11in">
          <fo:region-body margin="1in" margin-top="1.5in"/>
        </fo:simple-page-master>
      </fo:layout-master-set>
      <fo:page-sequence master-reference="my-page">
        <fo:flow flow-name="xsl-region-body">
          <xsl:apply-templates/>
        </fo:flow>
      </fo:page-sequence>
    </fo:root>
  </xsl:template>

  <xsl:template match="doc">
    <xsl:variable name="newline" select="'&#xA;'"/>        
    <xsl:variable name="MyVar">
      <xsl:choose>
        <xsl:when test="contains(//MyField,'AKA')">
          <xsl:value-of select="concat(substring-before(//MyField,'AKA'),$newline,substring-after(//MyField,'AKA'))"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="//MyField"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
    <fo:block linefeed-treatment="preserve">
      <xsl:value-of select="$MyVar"/>
    </fo:block>
  </xsl:template>

</xsl:stylesheet>

这是生成的 XSL-FO:

<fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
   <fo:layout-master-set>
      <fo:simple-page-master master-name="my-page" page-width="8.5in" page-height="11in">
         <fo:region-body margin="1in" margin-top="1.5in"/>
      </fo:simple-page-master>
   </fo:layout-master-set>
   <fo:page-sequence master-reference="my-page">
      <fo:flow flow-name="xsl-region-body">
         <fo:root>
            <fo:layout-master-set>
               <fo:simple-page-master page-height="11in" page-width="8.5in" master-name="my-page">
                  <fo:region-body margin-top="1.5in" margin="1in"/>
               </fo:simple-page-master>
            </fo:layout-master-set>
            <fo:page-sequence master-reference="my-page">
               <fo:flow flow-name="xsl-region-body">
                  <fo:block linefeed-treatment="preserve">John Doe 
 Johnny D</fo:block>
               </fo:flow>
            </fo:page-sequence>
         </fo:root>
      </fo:flow>
   </fo:page-sequence>
</fo:root>

PDF 是一个 8.5"x 11"页面，上面有这个:

John Doe
Johnny D

关于xml - 使用 XSL-FO 在 PDF 中添加换行符？，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/6764105/