我有一个依赖于 jsoncpp 的库，它是一个用 C++ 编写的 json 解析器。目前，jsoncpp 是稳定的并且不经常更新。它也已发布到公共(public)领域。现在，为了构建该库，依赖于 SCons 和 Python，它们可以工作，但对我的一些用户来说是一种烦恼。与其让他们下载 jsoncpp、SCons、Python，然后自己构建库，我可以直接将代码包含到我的项目中，然后一起构建所有内容。但是，这会导致一些问题。

主要是，如果我将 jsoncpp 代码包含到我的库中，那么我的库将包含 jsoncpp 符号。如果用户试图将我的库嵌入到已经依赖 jsoncpp 的库中，就会出现符号冲突。处理这个问题的正确方法是什么？例如，我可以分别编译我的库和 jsoncpp 并分发这两个库。如果用户已经有 jsoncpp，他们可以链接他们自己的版本。或者，我可以修改 jsoncpp 代码并将所有内容推送到新的命名空间中，但这看起来很麻烦。

如果有帮助，我会在 CMake 中构建所有内容，所以如果有 CMake 技巧来处理这个问题，那是最好的。

编辑

根据 Fraser 的建议，我有以下内容。

$ find .
.
./build
./build/jsoncpp-src-0.6.0-rc2.tar.gz
./src
./src/cpp
./src/cpp/hello.cpp
./src/cpp/CMakeLists.txt
./src/thirdparty
./src/thirdparty/jsoncpp
./src/thirdparty/jsoncpp/CMakeLists.txt
./src/thirdparty/CMakeLists.txt
./src/CMakeLists.txt

$ cat ./src/cpp/hello.cpp
#include <cstdlib>
#include <iostream>
#include <fstream>
#include <iomanip>
#include "json/json.h"

// Parses a JSON file and returns the root
void parse(const std::string& fname,Json::Value& root) {
    // Read in the input file
    Json::Reader reader;
    std::ifstream file(fname.c_str(),std::ifstream::in);
    bool parsingSuccessful = reader.parse( file, root, true );
    if (!parsingSuccessful) {
        std::cerr << "Failed to parse the optimization parameter "
            "file:  "  << reader.getFormattedErrorMessages() << std::endl;
        exit(EXIT_FAILURE);
    }

    // Close everything out 
    file.close();
}


int main(int argc,char* argv[]) {
    // Make sure we have the correct number of arguments
    if(argc!=2) {
        std::cout << "hello <json>" << std::endl;
        return EXIT_FAILURE;
    }

    // Parse the JSON files 
    Json::Value root;
    parse(argv[1],root);

    // Get the hello string
    std::string hello = root["Hello"].get("Message","Hello World!").asString();

    // Tell everyone
    std::cout << hello << std::endl;

    return EXIT_SUCCESS;
}

$  cat ./src/cpp/CMakeLists.txt 
project(hello)
cmake_minimum_required(VERSION 2.8.9)
enable_language(CXX)

# Set the location of jsoncpp
find_library(JSONCPP_LIBRARY
    NAMES json libjson
    PATHS ${CMAKE_BINARY_DIR}/installed/lib)
set(JSONCPP_LIBRARIES ${JSONCPP_LIBRARY} )
set(JSONCPP_INCLUDE_DIRS ${CMAKE_BINARY_DIR}/installed/include)

# Locate the headers
include_directories(${JSONCPP_INCLUDE_DIRS})

# Build the executable
add_executable(hello hello.cpp)

# Link jsoncpp
target_link_libraries(hello ${JSONCPP_LIBRARIES})

$ cat ./src/thirdparty/jsoncpp/CMakeLists.txt
project(jsoncpp)
cmake_minimum_required(VERSION 2.8.9)
enable_language(CXX)

# Set the source file prefix
set(source_prefix ${CMAKE_CURRENT_SOURCE_DIR}/src/lib_json/)

# Save the include directory
set(JSONCPP_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIRI}/include)

# Grab all the sources for the library
set(jsoncpp_srcs
    "${source_prefix}/json_reader.cpp"
    "${source_prefix}/json_value.cpp"
    "${source_prefix}/json_writer.cpp"
)

# Locate the headers
include_directories(${CMAKE_CURRENT_SOURCE_DIR}/include)

# Compile everything
set(CMAKE_POSITION_INDEPENDENT_CODE ON)
add_library(jsoncpp_object OBJECT ${jsoncpp_srcs})
add_library(jsoncpp_static STATIC $<TARGET_OBJECTS:jsoncpp_object> )
add_library(jsoncpp_shared SHARED $<TARGET_OBJECTS:jsoncpp_object> )
set_target_properties(jsoncpp_shared jsoncpp_static
    PROPERTIES OUTPUT_NAME json)

# Install the libraries and headers
install(TARGETS jsoncpp_static jsoncpp_shared DESTINATION lib)
install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/include/json DESTINATION include) 

$  cat ./src/thirdparty/CMakeLists.txt
project(third_party_libraries)
cmake_minimum_required(VERSION 2.8.9)

# Build jsoncpp
include(ExternalProject)
ExternalProject_Add(
    JsonCpp
    URL ${CMAKE_BINARY_DIR}/jsoncpp-src-0.6.0-rc2.tar.gz
    URL_MD5 363e2f4cbd3aeb63bf4e571f377400fb
    PATCH_COMMAND ${CMAKE_COMMAND} -E copy
        "${CMAKE_CURRENT_SOURCE_DIR}/jsoncpp/CMakeLists.txt"
        CMakeLists.txt
    CMAKE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=${CMAKE_BINARY_DIR}/installed
)

$ cat ./src/CMakeLists.txt
project(hello_example)
cmake_minimum_required(VERSION 2.8.9)

# First, build our TPLs 
add_subdirectory(thirdparty)

# Then, build our target
add_subdirectory(cpp)

基本上，我们使用 CMake 的 ExternalProject 脚本在本地编译并安装 jsoncpp 到构建目录。安装库后，我们可以将可执行文件链接到它。由于 jsoncpp 不包含 CMakeLists.txt，我们使用补丁程序将适当的 CMake 脚本插入到 jsoncpp 源结构中。在更高级的构建脚本中，我们可以选择是否使用此构建过程或让用户直接指定库。

无论如何，也许其他人会发现这很有用。它简化了某些用户的build设置，但并未将所有符号捆绑到某个大型库中。

最佳答案

如果你想让所有用户满意(我知道 - 不可能!)，你可以添加一个 option对于每个依赖项，例如选项(BuildJsonCpp)。

如果 option 为 ON，则构建依赖项，否则使用 find_library 和 find_path 包含它或 find_package。

为了构建依赖关系，而不是包含源代码，您可以考虑 ExternalProject CMake 模块。该模块用于下载、配置、构建和安装外部项目，并允许外部项目完全包含在您的构建树中，而不是您的源代码树中。

这将允许您在项目中只保留您自己的源文件，使其更小且更相关 - 特别是对于不希望构建依赖项的用户。

它会让您的 CMake 文件变得更复杂，更难维护，但我想如果您想让构建系统更灵活，这就是您必须付出的代价。

关于c++ - 将一个项目合并到另一个项目的方法，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/17821443/